topic Re: Keep 2 Variables based on conditions in SAS Programming

Keep 2 Variables based on conditions

marysmith — Wed, 31 Jan 2018 12:46:01 GMT

Hey guys,

I have a dataset with 9 Variables and 300 Observations. Now I want to keep some Observations based on some conditions.

I have a variable Notificationdate and I only need Observations between the 01/01/2014 and the 31/12/2016 and Observations where Art_der_Anzeige = Erstanzeige. I tried so many options but neither would work. Thank you!

data saspms.datensatz_new;
set saspms.datensatz_pms_neu;
where notificationdate <= 01/01/2014 & >= 31/12/2016 ;

where Art_der_Anzeige= Erstanzeige;
run;

data saspms.datensatz_new;
set saspms.datensatz_pms_neu;
keep if notificationdate <= 01/01/2014 & >= 31/12/2016 and keep if Art_der_Anzeige= Erstanzeige;
run;

Re: Keep 2 Variables based on conditions

Kurt_Bremser — Wed, 31 Jan 2018 13:00:19 GMT

Do this:

data saspms.datensatz_new;
set saspms.datensatz_pms_neu;
where '01jan2014'd <= notificationdate <= '31dec2016'd and Art_der_Anzeige = "Erstanzeige";
run;

Note:

character literals must be enclosed in quotes
date literals are specified in the above manner; other date notations only work in an input function with a proper informat

Re: Keep 2 Variables based on conditions

s_lassen — Wed, 31 Jan 2018 13:04:50 GMT

The KEEP statement is not used to limit the number of observations, but the number of variables. But the WHERE statement does what you want. Only you should limit it to one statement, which combines the two conditions. And then you need to change your SAS date constants (I assume that your dates are SAS dates in the format DDMMYY10.):

data saspms.datensatz_new;
  set saspms.datensatz_pms_neu;
  where '01JAN2014'd <= notificationdate <= '31DEC2016'D 
    and Art_der_Anzeige= Erstanzeige;
run;

Re: Keep 2 Variables based on conditions

marysmith — Wed, 31 Jan 2018 13:06:51 GMT

Thank you for your quick respond. But unfortunately I got an error message:
ERROR: WHERE clause operator requires compatible variables.
What does it mean?

Thank you so much!

Re: Keep 2 Variables based on conditions

Kurt_Bremser — Wed, 31 Jan 2018 13:08:18 GMT

Maxim 3: Know your data.

Run a proc contents on your dataset to determine variable types and assigned formats.

Re: Keep 2 Variables based on conditions

marysmith — Wed, 31 Jan 2018 13:14:51 GMT

Yeah I did that. Both a character Variables..

Re: Keep 2 Variables based on conditions

Kurt_Bremser — Wed, 31 Jan 2018 13:21:06 GMT

Then your first step should be converting your dates stored as character into real SAS date values. Since we now need to work with a newly created variable, switch from a where condition to a subsetting if:

data saspms.datensatz_new;
set saspms.datensatz_pms_neu;
format n_date ddmmyy10.;
n_date = input(notificationdate,ddmmyy10.);
if '01jan2014'd <= n_date <= '31dec2016'd and Art_der_Anzeige = "Erstanzeige";
run;

Re: Keep 2 Variables based on conditions

srinath3111 — Wed, 31 Jan 2018 13:25:52 GMT

data saspms.datensatz_new;
set saspms.datensatz_pms_neu;
where notificationdate between "01/01/2014"d and "31/12/2016"d and Art_der_Anzeige="Erstanzeige";
run;

Re: Keep 2 Variables based on conditions

srinath3111 — Wed, 31 Jan 2018 13:30:30 GMT

proc sql;

create table saspms.datensatz_new as

select * from saspms.datensatz_pms_neu where

notificationdate between("01/01/2014"d and "31/12/2016"d) and Art_der_Anzeige="Erstanzeige";

quit;

Re: Keep 2 Variables based on conditions

marysmith — Wed, 31 Jan 2018 14:05:51 GMT

Thank you so much! That helped me a lot.
But what if there is even more conditions? Just realized that I need something else. My Variable Art_der_Anzeige has 4 values: Erstanzeige, Änderungsanzeige, Beendigung, Abschlussbericht, I need all the cases where I have "Erstanzeige" between 2014-2016 and Änderungsanzeige/Abschlussbericht/Beendigung after 2014.
I tried it like this but it didnt work 😞
data saspms.versuch;
set saspms.datensatz_pms_neu;
format n_date1 ddmmyy10.;
n_date1 = input(notificationdate,ddmmyy10.);
if "01jan2014"d <= n_date1 Art_der_Anzeige = "Erstanzeige" or if Art_der_Anzeige NE "Erstanzeige" and n_date >= "01jan2014"d ;

Re: Keep 2 Variables based on conditions

Kurt_Bremser — Wed, 31 Jan 2018 14:20:56 GMT

The syntax for the subsetting if is this:

if condition ;

A condition is a piece of boolean logic; boolean operators are not, and, or.

So your second if is wrong syntax, it should be

if "01jan2014"d <= n_date1 <= '31dec2016'd and Art_der_Anzeige = "Erstanzeige" or Art_der_Anzeige ne "Erstanzeige" and n_date >= "01jan2014"d;

Note that, in boolean logic, not is evaluated before and, and and before or.