topic run 1 macro multiple time in SAS Programming

run 1 macro multiple time

hhchenfx — Tue, 30 Jan 2018 22:25:22 GMT

Hi Everyone,

I want to run a macro as below:

%macro check (var=var1);

%macro check(var=var2);

...

%macro check (var=var1000);

So I need to run it over a list of 1000 variable.

I have the list of the name in file "name"

Is there any way that I dont have to write the %check() 1000 time?

Thank you,

data source; 
input abc xyz var1 varx;
datalines;
1 0 0 0
0 2 0 1
1 1 1 2
;run;

data name; 
input  name $;
datalines;
abc
xyz
var1
varx
;run;

%macro check (var=);
data _temp_&var; set source;
if abc>0;
run;
%mend;

%check (var=abc);
%check (var=xyz);
%check (var=var1);
%check (var=varx);

Re: run 1 macro multiple time

Reeza — Tue, 30 Jan 2018 22:31:28 GMT

Look at CALL EXECUTE.

/********************************************************************
Example : Call macro using parameters from data set
********************************************************************/

proc sort data=sashelp.class out=class;
by age sex;
run;

%macro summary(age=, sex=);

proc print data=sashelp.class;
	where age=&age and sex="&sex";
run;

%mend;

data sample;
set class;
by age sex;

if last.sex;
string =
    catt('%summary(age=', age, ',sex=', sex, ');');
put string;
run;


data _null_;
set sample;
call execute(string);
run;

Re: run 1 macro multiple time

Reeza — Tue, 30 Jan 2018 22:31:29 GMT

Look at CALL EXECUTE.

/********************************************************************
Example : Call macro using parameters from data set
********************************************************************/

proc sort data=sashelp.class out=class;
by age sex;
run;

%macro summary(age=, sex=);

proc print data=sashelp.class;
	where age=&age and sex="&sex";
run;

%mend;

data sample;
set class;
by age sex;

if last.sex;
string =
    catt('%summary(age=', age, ',sex=', sex, ');');
put string;
run;


data _null_;
set sample;
call execute(string);
run;

Re: run 1 macro multiple time

art297 — Tue, 30 Jan 2018 22:38:59 GMT

I agree with @Reeza, but don't see why you'd even need a macro. I'd do something like the following:

data source; 
input abc xyz var1 varx;
datalines;
1 0 0 0
0 2 0 1
1 1 1 2
;run;

data name; 
input  name $;
datalines;
abc
xyz
var1
varx
;run;

data _null_;
  set name;
  length forexec $80;
  forexec=catt('data _temp_',name,';set source; if');
  call execute(forexec);
  forexec=catt(name,'>0;run;');
  call execute(forexec);
run;

Art, CEO, AnalystFinder.com