topic Re: PROC REPORT, can you place descriptive text in a BREAK or RBREAK row? in SAS Programming

PROC REPORT, can you place descriptive text in a BREAK or RBREAK row?

PaigeMiller — Fri, 26 Jan 2018 18:57:12 GMT

proc report data=sashelp.class;
    columns sex age height weight;
    define sex/group;
	define age/group;
    define height/analysis mean format=10.2 "Height Mean";
    define weight/analysis mean format=10.1 "Weight Mean";
	break after sex/summarize style=[font_style=italic];
	rbreak after/summarize style=[font_style=italic];
run;

I would like the BREAK rows to have the text at the left hand side in column 1 "Female Mean" or "Male Mean", and in the RBREAK row I'd like the text "Overall Mean". How can this be done?

Re: PROC REPORT, can you place descriptive text in a BREAK or RBREAK row?

Cynthia_sas — Fri, 26 Jan 2018 19:00:56 GMT

Hi:
You will need 2 COMPUTE blocks. Refer to the techniques shown in this paper: https://www.sas.com/content/dam/SAS/support/en/technical-papers/SAS0431-2017.pdf

cynthia

Re: PROC REPORT, can you place descriptive text in a BREAK or RBREAK row?

Ksharp — Sat, 27 Jan 2018 10:59:42 GMT

data class;
 length sex $ 40;
 set sashelp.class;
 sex=ifc(sex='F','Female','Male');
run;
proc report data=class nowd; 
    columns sex age height weight;
    define sex/group;
	define age/group;
    define height/analysis mean format=10.2 "Height Mean";
    define weight/analysis mean format=10.1 "Weight Mean";
	break after sex/summarize style=[font_style=italic];
	rbreak after/summarize style=[font_style=italic];
	compute after sex;
	  sex=catx(' ',sex,'Mean');
	endcomp;
	compute after;
	  sex=catx(' ','Overall','Mean');
	endcomp;
run;