topic Re: How to add blank rows for my report? in SAS Programming

How to add blank rows for my report?

chrisd9970 — Thu, 18 Jan 2018 14:45:02 GMT

I would like to add blank rows in between each subject group. Here's my data and I tried using PROC REPORT. However, the blank rows works only in the listings output. Didn't work on my report output. Since I use ODS EXCEL, the blank rows didn't work. Can anyone please help?

data report;
input variable $ value $ group ;
cards;

Sex F 1

Sex M 1

Age <18 2

Age 18-30 2

Age 31-50 2

Age >50 2;
run;

/* ods excel file='/mydirectory.report.xlsx'; */
proc report nofs data=report headline ;
columns group variable value ;
define group / order noprint ;
define variable / display ;
define value / display ;
break after group / skip ;
run;

/* ods excel close; */

Re: How to add blank rows for my report?

art297 — Thu, 18 Jan 2018 15:15:23 GMT

One way would be to add a compute block. e.g.:

data report;
  input variable $ value $ group ;
  cards; 
Sex F 1
Sex M 1
Age <18 2
Age 18-30 2
Age 31-50 2
Age >50 2
;
run;

/* ods excel file='/mydirectory.report.xlsx'; */
ods excel file='/folders/myfolders/report.xlsx';
proc report nofs data=report headline ;
  columns group variable value ;
  define group    / order noprint ;
  define variable / display ;
  define value     / display ;
/*   break after group / skip ; */
  compute after group;
    line ' ';
  endcomp;
run;

ods excel close;

Art, CEO, AnalystFinder.com

Re: How to add blank rows for my report?

chrisd9970 — Thu, 18 Jan 2018 15:29:18 GMT

Thank you very much. This is perfect!