topic Re: Delete column whose name certain characters in SAS Programming

Delete column whose name certain characters

hhchenfx — Sat, 13 Jan 2018 21:30:26 GMT

Hi Everyone,

I want to delete all columns that have name with string "ID" in it.

My data is like that

data have;
input abIc ID1 bxI4D b_ID2 xyzID_3;
cards;
1 2 3 4 5
;run;

So I only keep abIc and bxI4D.

Thank you for your help.

Re: Delete column whose name certain characters

Reeza — Sat, 13 Jan 2018 21:38:55 GMT

Not easily but you can build a list of variables from either PROC CONTENTS or SASHELP.VCOLUMN which has the list of variables.

Then include those in your DROP statement.

Re: Delete column whose name certain characters

novinosrin — Sat, 13 Jan 2018 21:51:16 GMT

data have;
input abIc ID1 bxI4D b_ID2 xyzID_3; 
cards;
1 2 3 4 5
;run;

proc sql;
select name into :drop_list separated by ' '
from sashelp.vcolumn
where libname="WORK" and memname="HAVE" and index(name,'ID')>0;
quit;

%put &drop_list;

data have;
set have;
drop &drop_list;
run;

Re: Delete column whose name certain characters

novinosrin — Sat, 13 Jan 2018 21:56:17 GMT

data have;
input abIc ID1 bxI4D b_ID2 xyzID_3; 
cards;
1 2 3 4 5
;run;

proc sql;
select name into :drop_list separated by ','
from sashelp.vcolumn
where libname="WORK" and memname="HAVE" and index(name,'ID')>0;
quit;

%put &drop_list;

proc sql;
   alter table have
      drop  &drop_list;
quit;

Re: Delete column whose name certain characters

hhchenfx — Sat, 13 Jan 2018 22:06:31 GMT

Thanks a lot.

HHC

Re: Delete column whose name certain characters

art297 — Sat, 13 Jan 2018 22:06:31 GMT

Same solution as @novinosrin but, if case is irrelevant, I'd suggest using FIND function rather than INDEX function.

data have;
  input abIc id1 bxI4D b_ID2 xyzID_3; 
  cards;
1 2 3 4 5
;run;

proc sql noprint;
  select name into :drop_list separated by ' '
  from sashelp.vcolumn
    where libname="WORK" and memname="HAVE" and find(name,'ID','i');
quit;

data want;
  set have;
  drop &drop_list;
run;

Art, CEO, AnalystFinder.com

Re: Delete column whose name certain characters

hhchenfx — Sat, 13 Jan 2018 22:23:46 GMT

So weird!

SAS only take all letter in CAP to run that code.

Here is the log:

3291 proc sql;
3292 select name into :drop_list separated by ','
3293 from sashelp.vcolumn
3294 where libname="WORK" and memname="myfile" and index(name,'ID')>0;
NOTE: No rows were selected.
3295 quit;
NOTE: PROCEDURE SQL used (Total process time):
real time 0.03 seconds
cpu time 0.03 seconds

3296
3297 proc sql;
3298 select name into :drop_list separated by ','
3299 from sashelp.vcolumn
3300 where libname="WORK" and memname="MYFILE" and index(name,'ID')>0;
3301 quit;
NOTE: PROCEDURE SQL used (Total process time):
real time 0.03 seconds
cpu time 0.00 seconds

Re: Delete column whose name certain characters

novinosrin — Sat, 13 Jan 2018 22:25:04 GMT

memname is always stored as UPCASE in metadata

Re: Delete column whose name certain characters

art297 — Sat, 13 Jan 2018 22:37:10 GMT

@novinosrin: Maybe that's true for Windows, but not for all operating systems. That's why I suggested the find function using the 'i' modifier.

Oops! Just read your post more carefully! Yes, libname and memname have to be in upper case. However, the variable names are case sensitive on some operating systems.

Art, CEO, AnalystFinder.com