topic Re: Retain in SAS Programming

Retain

Sama1 — Thu, 28 Dec 2017 05:39:36 GMT

Hi
Recently I started learning SAS , I need help with retain statement
I have the following dataset

Id xyz
A 1
A 2
A 3
A 4
B 1
B 2
B 3
B 4

I want to retain second observation in each group and reassign its value in 4th observation ..like

Id xyz
A 1
A 2
A 3
A 2
B 1
B 2
B 3
B 2

Thanks

Re: Retain

Sama1 — Thu, 28 Dec 2017 05:40:05 GMT

Re: Retain

novinosrin — Thu, 28 Dec 2017 06:05:44 GMT

A nice home work 🙂

data have;
input Id $ xyz;
datalines;
A 1
A 2
A 3
A 4
B 1
B 2
B 3
B 4
;

data want;
do _n_=1 by 1 until(last.id);
set have;
by id;
if _n_=2 then _t=xyz;
else if _n_=4 then xyz=_t;
output;
end;
drop _:;
run;

Re: Retain

novinosrin — Thu, 28 Dec 2017 06:08:51 GMT

Or since you desire traditional retain statement method, here you go:

data want;
set have;
by id;
retain _t;
if first.id then n=0;
n+1;
if n=2 then _t=xyz;
else if n=4 then xyz=_t;
drop n _t;
run;

Re: Retain

Sama1 — Thu, 28 Dec 2017 06:10:44 GMT

Thank you very much 👍☺️

Re: Retain

Reeza — Thu, 28 Dec 2017 19:16:31 GMT

Please mark the appropriate response (not this one) as the correct answer so that we know your question is resolved.