topic Re: SORTING in SAS Programming

SORTING

Vahe_Mar — Fri, 24 Nov 2017 07:52:42 GMT

Hi, how can I sort more then 2 datas same time by one variable which available in every data.

Re: SORTING

AllanBowe — Fri, 24 Nov 2017 08:19:23 GMT

Assuming you mean datasets (and that they have the same structure), you can do this by creating a view and sorting that - eg:

data one;
  x=1;y=2; output;
  x=1;y=3; output;
data two;
  x=4;y=6; output;
  x=0;y=7; output;
data sortview /view=sortview;
  set one two;
proc sort data=sortview out=final;
  by x;
run;

Re: SORTING

Vahe_Mar — Fri, 24 Nov 2017 08:35:27 GMT

Hi Allan Bowe, I mean all datas have same variable and need to sort before set

Re: SORTING

AllanBowe — Fri, 24 Nov 2017 09:06:32 GMT

ok - I'm going to assume you didn't necessarily mean that the datasets had to be sorted at the same time (which is possible, using rsubmit or other techniques). If you are happy for the datasets to be sorted in sequence, here is a simple macro solution:

data one;
x=1;y=2; output;
x=1;y=3; output;
data two;
x=4;y=6; output;
x=0;y=7; output;
data three;
x=6;y=6; output;
x=6;y=7; output;

%macro sortandappend(datasets=,var=x,outds=outds);
%local i;
%do i=1 %to %sysfunc(countw(&datasets));
  %let ds=%scan(&datasets,&i);
  proc sort data=&ds;
    by &var;
  run;
%end;
data &outds;
  set &datasets;
run;
%mend;

%sortandappend(datasets=one two three,var=x,outds=outds)

You provide a list of input datasets to the macro (one, two and three), set the variable to sort by, and the dataset to create.

Re: SORTING

Vahe_Mar — Fri, 24 Nov 2017 09:13:43 GMT

what you think about this ?

%Macro VR(data, sort);
proc sort data=&data;
by &sort;
run;
%mend vr;

data rm;
length macro $100;
set sashelp.vtable;
where libname="WORK" and memname ~in("_SV", "__MVALLRAW");;
macro='%VR(' || strip(memname) || ", _PATIENT_DISPLAY_ID_FULL" || ");";

run;

%macro VV;

proc sql;
select macro into:macro separated by " " from rm;
quit;
&macro;
%mend VV;
%VV;

Re: SORTING

Kurt_Bremser — Fri, 24 Nov 2017 09:21:36 GMT

You can call the %vr macro with call execute() from the data step, the second macro is not needed.

Re: SORTING

Vahe_Mar — Fri, 24 Nov 2017 09:24:00 GMT

without second macro i have errors about "by"

Re: SORTING

RW9 — Fri, 24 Nov 2017 09:29:11 GMT

Your not really providing any information. What datasets do you mean, do they have a common name, like ds1 ds2 which we can use, will they all have different names, is it all datasets in a given library? If its all in a library then:

data _null_;
  set sashelp.vtable (where=(libname="YOURLIB"));
  call execute(cats('proc sort data=yourlib.',memname,'; by var1; run;'));
run;