topic Re: How to remove last repeated same word more then once? in SAS Programming

How to remove last repeated same word more then once?

rajeshalwayswel — Wed, 22 Nov 2017 04:04:35 GMT

data have;
input a $ 30.;
cards;
abc %ak% %ak%
hjk %kl% %kl%
hygllllkjk %ko% %ko%
run;

Required Output:

abc %ak%

hjk %kl%

hygllllkjk %ko%

Re: How to remove last repeated same word more then once?

art297 — Wed, 22 Nov 2017 05:03:38 GMT

Here is one way:

data have;
  informat a $30.;
  length b $30;
input a &;
cards;
abc %ak% %ak%
hjk %kl% %kl%
hygllllkjk %ko% %ko%
;
run;

data want (drop=i j);
  set have;
  array test(999) $ _temporary_;
  i=1;
  j=0;
  do while (scan(a,i,' ') ne '');
    if scan(a,i,' ') not in test then do;
      j+1;
      test(j)=scan(a,i,' ');
    end;
    i+1;
  end;
  do i=1 to j;
    b=catx(' ',b,test(i));
  end;
run;

Art, CEO, AnalystFinder.com

Re: How to remove last repeated same word more then once?

RW9 — Wed, 22 Nov 2017 09:32:00 GMT

Assumes your test data reflects your data!:

data want;
 set have;
 name=scan(a,1);
 other=scan(a,2,"%");
run;

Re: How to remove last repeated same word more then once?

Ksharp — Wed, 22 Nov 2017 12:36:37 GMT

data have;
input a $30.;
cards;
abc %ak% %ak%
hjk %kl% %kl%
hygllllkjk %ko% %ko%
hygllllkjk %ko%
;
run;

data want;
 set have;
 want=prxchange('s/(\s+\S+)(\1)+$/\1/',-1,strip(a));
run;