topic Re: How to output histogram database in SAS Programming

How to output histogram database

hua — Mon, 13 Nov 2017 21:05:03 GMT

Hello all,

I'm using proc univariate to create a histogram of my data, anyone knows how to output the midpoints of each bin and the corresponding percentage?

The code I use is:

proc univariate data=have;
where Prep>=0.5 and Prep<130.5;
histogram Prep / endpoints=(0.5 to 130 by 5);
run;

By using this code, I could get the histogram, with my own defined endpoint and interval. But I don't know how to output a table (dataset) including the midpoints (or endpoints) and its percentage.

Proc freq can produce the percentage of every value in my data, but not for the bins.

Thanks!

Re: How to output histogram database

Reeza — Mon, 13 Nov 2017 21:06:47 GMT

Have you tried capturing the ODS Table?

https://blogs.sas.com/content/iml/2017/01/09/ods-output-any-statistic.html

Re: How to output histogram database

hua — Mon, 13 Nov 2017 21:17:36 GMT

Hi Reeza, I read the link, but I don't think ODS can help to output the midpoints and percentage, because there has no options for the table I want. Or could you tell me more details about it? Thank you so much!

Re: How to output histogram database

Reeza — Mon, 13 Nov 2017 21:22:19 GMT

Did you try it and it didn't work, or did you make that decision before trying it?

@hua wrote:
Hi Reeza, I read the link, but I don't think ODS can help to output the midpoints and percentage, because there has no options for the table I want. Or could you tell me more details about it? Thank you so much!

Re: How to output histogram database

hua — Mon, 13 Nov 2017 21:24:24 GMT

Yes, I tried. I use "ODS OUTPUT HistogramBins=output;", but it doesn't work here.

Re: How to output histogram database

Reeza — Mon, 13 Nov 2017 21:25:06 GMT

The output wasn't named HistogramBins in the ODS TRACE step...

Re: How to output histogram database

Reeza — Mon, 13 Nov 2017 21:25:35 GMT

You can also check the documentation for the ODS table name.

Re: How to output histogram database

hua — Mon, 13 Nov 2017 21:32:39 GMT

Hi Reeza, this is what I found, I think the table name is HistogramBins, did I misunderstand this option?

Re: How to output histogram database

Reeza — Mon, 13 Nov 2017 21:35:06 GMT

Nope, but it does appear the documentation may be wrong. This is why I recommend the ODS TRACE options instead - run the proc with ODS TRACE ON; <procedure code> ;; ODS TRACE OFF; Then capture the name from the log.

Try Histogram instead, this works for me - SAS 9.4 TS1M4

ods table histogram=want;;
proc univariate data=sashelp.cars;
histogram mpg_highway / endpoints=(0 to 80 by 5);;
run;

Re: How to output histogram database

hua — Mon, 13 Nov 2017 21:41:45 GMT

Yes, the Histogram works. And the log do show "histogram" when I use ods trade on and ods trade off. Sorry, I didn't realized I could capture the name before. Thank you for help! thank you so much, Reeza.

Re: How to output histogram database

ballardw — Mon, 13 Nov 2017 22:46:27 GMT

@hua wrote:

Hi Reeza, this is what I found, I think the table name is HistogramBins, did I misunderstand this option?

You may have missed the part that the Bins or HistogramBins are only created if you use MIDPERCENTS option on the HIstogram statement.

Re: How to output histogram database

Reeza — Mon, 13 Nov 2017 23:55:32 GMT

@ballardw I checked that, still doesn't work. It's a mistake in the documentation.

Re: How to output histogram database

ballardw — Tue, 14 Nov 2017 00:17:37 GMT

@Reeza wrote:

@ballardw I checked that, still doesn't work. It's a mistake in the documentation.

ARGGH! I tend to believe the documentation for features I don't use...

Re: How to output histogram database

Reeza — Tue, 14 Nov 2017 00:19:20 GMT

@ballardw wrote:

@Reeza wrote:

@ballardw I checked that, still doesn't work. It's a mistake in the documentation.

ARGGH! I tend to believe the documentation for features I don't use...

I double checked, I was wrong and the documentation is sort of right.

1. It's MIDPERCENTS - not MIDPOINTS which I had tested. When you use MIDPERCENTS it does produce a table called HistogramBins. Otherwise the table is called Histogram. Which isn't listed in the list.

The inconsistency still doesn't make sense.

Re: How to output histogram database

Rick_SAS — Tue, 14 Nov 2017 14:17:10 GMT

The easiest way to do this is to use the OUTHIST= option on the HISTOGRAM statement:

proc univariate data=sashelp.cars;
var mpg_city;
histogram mpg_city / midpoints=(5 to 65 by 10)outhist=want;
run;

proc print data=want; run;

Re: How to output histogram database

hua — Tue, 14 Nov 2017 15:17:05 GMT

Yes, it works. By the way, do you know how to get the dataset only without printing the histogram and all the other tables under OUTPUT window? I tried "noprint", but it seems like nothing changed. Thank you, Rick!

Re: How to output histogram database

Rick_SAS — Tue, 14 Nov 2017 15:23:33 GMT

Use NOPRINT to suppress the tables and use NOPLOT on the HISTOGRAM statement:

proc univariate data=sashelp.cars noprint;
var mpg_city;
histogram mpg_city / midpoints=(5 to 65 by 10) noplot outhist=want;
run;

Re: How to output histogram database

hua — Tue, 14 Nov 2017 15:25:44 GMT

Yes. Also I used "ods select none;" instead of "noprint", and it suppressed all the displays, too. Thank you!

Re: How to output histogram database

Rick_SAS — Tue, 14 Nov 2017 15:28:11 GMT

The difference is efficiency: When you use ODS SELECT NONE, the procedure computes everything and sends it to ODS, which then does not display it. When you use NOPRINT and NOPLOT, the procedure computes only the statistics that are needed for the output data sets.

Re: How to output histogram database

hua — Tue, 14 Nov 2017 15:32:00 GMT

I got it! Then I will choose to use NOPRINT and NOPLOT. 🙂 Thanks!