topic Re: Year wise claim count and sum of payments in SAS Programming

Year wise claim count and sum of payments

ambadi007 — Mon, 13 Nov 2017 13:15:13 GMT

HI ,

I have a data set like below

Year Claim Loss_paid Loss_Incured
2008 100         500              100
2008 200        1000             200
2009 300         2000          300
2009 400       3000           400

I need to get an output like

Year Claim_Count Loss_PAid Loss_incured
2008 2 1500 300
2009 2 5000 700

Year wise claims counts and sum value of Loss_paid and Loss_Incured

Re: Year wise claim count and sum of payments

PeterClemmensen — Mon, 13 Nov 2017 13:34:52 GMT

like this?

data have;
input Year Claim  Loss_paid  Loss_Incured;
datalines;
2008 100         500              100
2008 200        1000             200
2009 300         2000           300
2009 400        3000           400
;

proc sql;
	create table want as
	select year
	      ,count(Claim) as Claim_Count
		  ,sum(Loss_paid) as Loss_paid
		  ,sum(Loss_Incured) as Loss_Incured
	from have
	group by year;
quit;

Re: Year wise claim count and sum of payments

andreas_lds — Mon, 13 Nov 2017 14:44:06 GMT

Not clear what you need: dataset or report. If you need a report, try

proc report data=have;
   define Year / group;
   define Claim / n;
   define Loss_Paid / sum;
   define Loss_Incured / sum;
run;

Re: Year wise claim count and sum of payments

ballardw — Mon, 13 Nov 2017 15:52:34 GMT

and another way to create a data set:

proc summary data=have nway;
  class year;
  var loss_paid loss_incured;
  output out=want (drop=_type_ rename=(_freq_=claim_count)) 
      sum=;
run;