topic Re: array q in SAS Programming

array q

eric2 — Thu, 09 Nov 2017 20:18:29 GMT

data a;
input subject $ visit $ labdt $ cd1 $ cd2 $ cd3 $ cd4 $;
cards;
101 1 15JUN15 17JUN15 18JUN15 29JUN15 31AUG15
101 2 20JUN15 17JUN15 18JUN15 29JUN15 31AUG15
101 3 01AUG15 17JUN15 18JUN15 29JUN15 31AUG15
102 1 19JUN15 17JUN15 28JUN15 29JUN15 31SEP15
102 1 28JUN15 17JUN15 28JUN15 29JUN15 31SEP15
;
run;

data b;
set a;
by subject visit;
array vis[*] cd1-cd4;
do i = 1 to dim(vis);

if input(labdt,date9.) le input(vis[i],date9.) then chk=vlabel(vis[i]);
else if input(labdt,date9.) < input(vis[i],date9.) and input(labdt,date9.) ge input((vis[i+1]),date9.)
then chk=vlabel(vis[i+1]);
end;

run;

why isnt chk assgined properly. basically i want to check if labdt falls between which cdx variables?

thk

Re: array q

Reeza — Thu, 09 Nov 2017 20:26:15 GMT

You should consider a binary search method instead of looping through the entire array as well...though it's likely the easiest approach.

You don't have a LEAVE, which you should, once your condition is met, otherwise, it will check each i regardless.

Re: array q

ballardw — Thu, 09 Nov 2017 20:38:45 GMT

Do you get the same invalid data notes that I do when I run your code? 31SEP15 is not a valid date.

Is there any reason the dates weren't created as date values with the appropriate informat when created? I find that having actual date values usually simplifies code a lot.

You might show what your are expecting to get for a result.

I think that you may have the direction of your comparisons backwards in the ELSE if, your loop is going to attempt to execute one too many times for most cases. If you want to stop as soon as you find the boundary value/variable the below shows an example.

data a;
input subject $ visit $ labdt $ cd1 $ cd2 $ cd3 $ cd4 $;
cards;
101 1 15JUN15 17JUN15 18JUN15 29JUN15 31AUG15
101 2 20JUN15 17JUN15 18JUN15 29JUN15 31AUG15
101 3 01AUG15 17JUN15 18JUN15 29JUN15 31AUG15
102 1 19JUN15 17JUN15 28JUN15 29JUN15 30SEP15
102 1 28JUN15 17JUN15 28JUN15 29JUN15 30SEP15
;
run;

data b;
   set a;
   by subject visit;
   array vis[*] cd1-cd4;
   do i = 1 to (dim(vis) -1);

      if input(labdt,date7.) le input(vis[i],date7.) then do; 
         chk=vlabel(vis[i]);
         leave;
      end;
      else if input(labdt,date7.) ge input(vis[i],date7.) and input(labdt,date7.) le input((vis[i+1]),date7.)
      then do;
         chk=vlabel(vis[i+1]);
         leave;
      end;
   end;

run;

This assumes that the cd1 to cd4 are sorted in ascending order.

Re: array q

eric2 — Thu, 09 Nov 2017 20:39:15 GMT

thx LEAVE worked ..

thx again

Re: array q

Astounding — Thu, 09 Nov 2017 20:44:24 GMT

If that's all you did, you will get error messages on some days, and not on other days. It depends on what is in the data. If you get as far as I=4, then what do you think will happen when your code references vis[I+1] ??

Re: array q

eric2 — Thu, 09 Nov 2017 20:58:05 GMT

i could have used full dates instead of date7. i believe the date will fall under one category only so do you think backward will produce different result than the current one?

Re: array q

ballardw — Thu, 09 Nov 2017 21:22:42 GMT

@eric2 wrote:

i could have used full dates instead of date7. i believe the date will fall under one category only so do you think backward will produce different result than the current one?

If I understand your question, likely the choice of date7 vs date9 shouldn't matter. I just try to match the informat to actual range of characters/digits I have as there are some times that a longer informat than the value may cause problems.

If the original dates had been read using date7 informat then the comparison code would be much cleaner and easier to follow.

Plus if you need to do anything else, such as the difference between the test date and the boundary date you would have to convert the values again to use intck function.

Re: array q

PGStats — Fri, 10 Nov 2017 04:39:07 GMT

If CD1 <= CD2 <= CD3 <= CD4 then you must stop the loop as soon as labdt <= CDi

data b;
set a;
array vis[*] cd1-cd4;
do i = 1 to dim(vis);

    if input(labdt,date9.) le input(vis[i],date9.) then do;
        chk=vlabel(vis[i]);
        leave;
        end;
    end;

run;