topic Re: MACRO with %IF (...) IN (...) in SAS Programming

MACRO with %IF (...) IN (...)

x2PSx — Wed, 08 Nov 2017 20:08:05 GMT

Hello, my macro doesn't work the way I want to. So basically this below works perfectly:

%MACRO mymacro() ;
%IF %substr(&n50prc0_aaaamm.,5,2) = 06
%THEN %DO;
[...]

However I would need something like this because I want every trimester to work

%MACRO mymacro() ;
%IF %substr(&n50prc0_aaaamm.,5,2) in (03,06,09,12)
%THEN %DO;
[...]

I tried many different things including different options like MINDELIMITER but nothing seems to work for me. Thank you for your help

Re: MACRO with %IF (...) IN (...)

collinelliot — Wed, 08 Nov 2017 20:14:18 GMT

Are you using the "MINOPERATOR" option?

Re: MACRO with %IF (...) IN (...)

x2PSx — Wed, 08 Nov 2017 20:19:39 GMT

Yes, with this

options MINOPERATOR;
%MACRO mymacro / MINDELIMITER=",";
%IF %substr(&n50prc0_aaaamm.,5,2) in (03,06,09,12)
%THEN %DO;
[...]

I get this error:

ERROR 13-12: Unrecognized SAS option name, MINOPERATOR.

2 %MACRO RAPPEL_PROD / MINDELIMITER=",";
ERROR: Extraneous information on %MACRO statement ignored.
ERROR: A dummy macro will be compiled.
3

Re: MACRO with %IF (...) IN (...)

Astounding — Wed, 08 Nov 2017 20:24:20 GMT

Macro language does support an IN operator. As @collinelliot indicated, you need two options properly set, plus the matching syntax in your code. Tedious, but it is possible. (For example, get rid of the parentheses around the list of values.)

An easy workaround for this case might (depending on the range of values) be:

%let two_digits = %substr(&n50prc0_aaaamm.,5,2);

%if &two_digits = &two_digits / 3 * 3 %then %do;

This statement would apply integer arithmetic (truncating remainders).

Re: MACRO with %IF (...) IN (...)

Tom — Wed, 08 Nov 2017 20:32:48 GMT

What version of SAS are you using?

791  %put &sysver ;
9.4

You could use a little arithmetic. Try this little test.

%macro test;
  %do m=1 %to 12 ;
    %let mm=%sysfunc(putn(&m,z2));
    %let mod4=%sysfunc(mod(&mm,4));
    %put &=m &=mm &=mod4 ;
    %if not %sysfunc(mod(&mm,4)) %then %put Found end of quarter ;
  %end;
%mend ;
%test;

Re: MACRO with %IF (...) IN (...)

Reeza — Wed, 08 Nov 2017 21:39:19 GMT

You need single quotes in the MINDELIMITER

This works for me:

%MACRO myMacro(n50prc0_aaaamm=) / mindelimiter=',' minoperator ;
%IF %substr(&n50prc0_aaaamm.,5,2) in (03,06,09,12)
%THEN %DO;

%PUT &n50prc0_aaaamm. -> MATCH;

%END;
%ELSE %DO;
%PUT &n50prc0_aaaamm. -> NO MATCH;

%END;

%MEND myMacro;

%mymacro(n50prc0_aaaamm=199501);
%mymacro(n50prc0_aaaamm=199502);
%mymacro(n50prc0_aaaamm=199503);
%mymacro(n50prc0_aaaamm=199504);
%mymacro(n50prc0_aaaamm=199505);
%mymacro(n50prc0_aaaamm=199506);
%mymacro(n50prc0_aaaamm=199509);
%mymacro(n50prc0_aaaamm=199512);
%mymacro(n50prc0_aaaamm=199513);

Re: MACRO with %IF (...) IN (...)

x2PSx — Wed, 08 Nov 2017 21:51:52 GMT

thank you, but it doesn't for me. I should mention that I run this SAS code via a secure shell. My first code does work though, but I don't think the options are recognized

Re: MACRO with %IF (...) IN (...)

Reeza — Wed, 08 Nov 2017 21:56:00 GMT

@x2PSx then likely Tom has the correct idea, you're working on an older version of SAS that doesn't support MINDELIMITER - which would be pretty old. Did you verify the SAS version? Or are you using WPS? That doesn't work the same either.

Re: MACRO with %IF (...) IN (...)

x2PSx — Wed, 08 Nov 2017 22:00:57 GMT

That is a very nice shortcut indeed for my specific problem, thank you

Re: MACRO with %IF (...) IN (...)

x2PSx — Wed, 08 Nov 2017 22:02:23 GMT

I work with SAS 9.3 TS Level 1M1 W32_7PRO

Re: MACRO with %IF (...) IN (...)

Reeza — Wed, 08 Nov 2017 22:45:43 GMT

MINDELIMITER has been available as of SAS 9.2+