topic is there one way to solve fractional programming with SAS? in Mathematical Optimization, Discrete-Event Simulation, and OR

is there one way to solve fractional programming with SAS?

dali74 — Mon, 20 Nov 2017 16:58:07 GMT

If we have this problem (you can see it in https://www.slideshare.net/orajjournal/a-single-stage-single-constraints-linear-fractional-programming-problem-an-approach), can we solve with SAS?

Re: is there one way to solve fractional programming with SAS?

art297 — Mon, 20 Nov 2017 17:30:35 GMT

There are a number ways. Take a look at: https://blogs.sas.com/content/iml/2016/12/19/solve-linear-programming-problems-sas.html

Art, CEO, AnalystFinder.com

Re: is there one way to solve fractional programming with SAS?

RobPratt — Mon, 20 Nov 2017 17:40:16 GMT

Here are three ways:

/* linear fractional programming problem (NLP) */
proc optmodel;
   var x {1..2} >= 0;
   max z = (x[1] + 3) / (x[2] + 1);
   con c1: -x[1] + x[2] <= 1;
   con c2: 2*x[1] <= 3;
   con c3: 3*x[1] + 2*x[2] <= 7;
   solve;
   print x;
quit;

/* linear programming transformation from Das/Mandal paper (LP) */
proc optmodel;
   var y {1..2} >= 0;
   max z = y[1] - y[2] + 3;
   con c1: -y[1] + 2*y[2] <= 1;
   con c2: 2*y[1] <= 3;
   con c3: 3*y[1] + 9*y[2] <= 7;
   solve;
   print y;
quit;

/* linear programming problem from Charnes/Cooper transformation (LP) */
/* https://en.wikipedia.org/wiki/Linear-fractional_programming#Transformation_to_a_linear_program */
proc optmodel;
   var y {1..2} >= 0;
   var t >= 0;
   max z = y[1] + 3*t;
   con c1: -y[1] + y[2] <= t;
   con c2: 2*y[1] <= 3*t;
   con c3: 3*y[1] + 2*y[2] <= 7*t;
   con c4: y[2] + t = 1;
   solve;
   print y;
   impvar x {j in 1..2} = y[j].sol / t.sol;
   print x;
quit;

Re: is there one way to solve fractional programming with SAS?

Ksharp — Tue, 21 Nov 2017 13:34:51 GMT

SAS/IML also can do that . If you want IML solution, post it at IML forum. Rick is there.