Horizontal lines in Proc Report

asumsie — Tue, 01 May 2012 18:48:26 GMT

Hello!

I am trying to put horizontal lines between subject identifiers in a RTF output and the following comes close:

compute before subjid / style={bordertopcolor=black bordertopwidth=3};

line '';

endcomp;

However, I want a solution that does not create an extra blank line inserted as this creates too much white space. Thanks in advance.

Re: Horizontal lines in Proc Report

Cynthia_sas — Wed, 02 May 2012 00:00:03 GMT

Hi:

Without seeing all your code or the style that you are using, it is hard to guess what the rest of your code looks like. But do you want something like the cyan-colored lines in the attached screenshot?

If so, instead of doing a COMPUTE before, try just using a COMPUTE for SUBJID with a CALL DEFINE statement to change the _ROW_ style attributes, as shown in the test code below.

cynthia

ods listing close;
options center orientation=portrait nodate nonumber
topmargin=1in bottommargin=1in
rightmargin=1in leftmargin=1in;

data test;
set sashelp.class;
subjid=catt(sex,age);
run;
title; footnote;

ods rtf file='c:\temp\bordertest.rtf' style=journal;
proc report data=test nowd;
column subjid name height weight;
define subjid / group ;
define name / order;
define height / sum;
define weight / sum;
compute subjid ;
       if subjid gt ' ' then
       call define(_row_,'style',
                  'style={bordertopcolor=cyan bordertopwidth=3}');
endcomp;
run;
ods rtf close;

Re: Horizontal lines in Proc Report

asumsie — Wed, 02 May 2012 16:22:13 GMT

Great, thanks Cynthia.

topic Re: Horizontal lines in Proc Report in ODS and Base Reporting

Horizontal lines in Proc Report

Re: Horizontal lines in Proc Report

Re: Horizontal lines in Proc Report