topic Re: Problem with Tagset.ExcelXP and style=minimal in ODS and Base Reporting

Problem with Tagset.ExcelXP and style=minimal

deleted_user — Wed, 20 Dec 2006 19:42:35 GMT

I am trying to use the tagsets.excelXP with the style set to minimal to output a report to an excel file. If there are numeric missing values, excel won't open the file created. If I use a different style, such as SASDocPrinter, excel opens the file with no problems. I searched the SAS website but I didn't see anything about this.

Has anyone else had this problem? I am using the most current (June 2006) tagset definition and I am using SAS 9.1.3 service pack 3 on a WinXP machine. I've included a small program that recreates my problem.

data test;
input a b c;
cards;
1 2 3
3 . 2
0 0 3
;
run;

ods tagsets.excelXP file="c:\junk.xls" style=minimal;

proc print data=test;
run;

ods tagsets.excelXP close;

Re: Problem with Tagset.ExcelXP and style=minimal

Cynthia_sas — Wed, 20 Dec 2006 19:58:04 GMT

Cory:
I'm not sure the problem is with your data. I tested an October (working/not final) version of the ExcelXP tagset and I do not believe it had a problem with style=minimal.

In the meantime, however, if you look at this code (after you run it and use it), you should see something very similar to what you get with style=minimal and this style does work with the June tagset that's out on the ODS MARKUP web site.
[pre]
** Modify the XLStatistical style to get rid of;
** all border lines, colors, etc;
proc template;
define style styles.XLStatistical;
parent = styles.Statistical;
style Body from Body/
background=_undef_;
style table from Output /
background=_undef_
foreground=_undef_
borderwidth=_undef_
font_size=10pt;
style Header from Header /
background=_undef_
foreground=_undef_
borderwidth=_undef_
font_size=10pt;
style RowHeader from RowHeader /
background=_undef_
foreground=_undef_
borderwidth=_undef_
font_size=10pt;
style Data from Data /
background=_undef_
foreground=_undef_
borderwidth=_undef_
font_size=10pt;
end;
run;

ods tagsets.excelxp file='c:\temp\use_style.xls'
style=styles.XLStatistical;
[/pre]
If you need an updated copy of the ExcelXP tagset so you can use style=minimal, you will have to contact Tech Support.

Good luck!

cynthia

Re: Problem with Tagset.ExcelXP and style=minimal

deleted_user — Wed, 20 Dec 2006 20:37:09 GMT

Cynthia,

That worked, thanks!

I can wait until the next version of the ExcelXP tagset is released to use the minimal style.

Thanks again

Cory