topic Re: TAGSETS.EXCELXP indent cell contents. in ODS and Base Reporting

TAGSETS.EXCELXP indent cell contents.

data_null__ — Wed, 15 Sep 2010 14:08:27 GMT

If I want to indent the cell contents of a column is there an option?

It appears that tagset would need to add INDENT to the XML as below.

This is original XML
[pre]

Re: TAGSETS.EXCELXP indent cell contents.

Eric_SAS — Wed, 15 Sep 2010 18:59:02 GMT

Indent is a style attribute. It can be defined in a style element or as a style over-ride. This example shows both ways, It just depends upon which classlev statement you use. With proc print, report or tabulate the style or over ride can be specified in many ways.

proc template;
define style mystyle;
parent=styles.default;
style myclasslev from data/
indent=10;
end;
run;

ods listing close;
ods pdf file="file.pdf" style=mystyle;
ods tagsets.excelxp file='temp.xls' style=mystyle;
title ;footnote;
proc tabulate data=sashelp.class; * missing;
class name age / order=data;
/*classlev name / s=myclasslev;*/
classlev name / s=data[indent=10];
table name=' ' all="Total",
age=' '*(N COLPctN='%') / box="Agegp" ;
run;

ods _all_ close;

Re: TAGSETS.EXCELXP indent cell contents.

data_null__ — Wed, 15 Sep 2010 20:30:50 GMT

Thanks so much, just what I needed to see. Here is example of what I was trying to do.

[pre]
proc template;
define style mystyle;
parent=styles.default;
style rightIndent from data /
indent=4
just=right;
end;
run;

ods tagsets.excelxp file='temp006.xml' style=mystyle;
proc report nowd data=sashelp.class;
define _numeric_ / display style(column)=rightIndent;
run;
ods _all_ close;
[/pre]