topic proc report and across in ODS and Base Reporting

proc report and across

asishgautam — Thu, 25 Aug 2011 16:18:37 GMT

Hi I have a data set arranged as follows:

Utility Year Sector Load

I know that I can use the "across" keyword in proc report so that i can show load by sector but I want to supress the printing of the label "Sector".

------------------Sector---------------------

Utility Year Residential Commercial Industrial

What I want to do in proc report is to apply the "across" to the column labeled "Sector" but I want my results displayed as below:

Utility Year Residential Commercial Industrial

I think I can use proc transpose to rotate the data but I would like to avoid having to create another intermediate table if possible.

Thanks.

proc report and across

NN — Thu, 25 Aug 2011 16:55:50 GMT

Hi,

Read about the define statement in proc report.

What you are looking for is

define sector / across "";

The blank quotes will supress the label.

proc report and across

asishgautam — Fri, 26 Aug 2011 18:29:36 GMT

NN: your answer does what I want but now I have another complication.

this is my code:

proc report data = Consumpt nowd split ='\' ;

column PAN Year Sector,High High=stot ;

define PAN / group noprint ;

define Year / group ;

define Sector / across "" format = Sectorid. order = internal ;

define High / "" analysis STYLE(column)={TAGATTR='format:#,##0'} ;

define stot / 'Total Consumption' sum STYLE(column)={TAGATTR='format:#,##0'} ;

where put(PAN,Paid.) = "IID" ;

quit ;

here is the result (example table):

but what i need is this format:

are there some options that i need to use to control how columns are placed to fix the layout?

proc report and across

NN — Fri, 26 Aug 2011 18:38:40 GMT

Hi,

Read about spanned headers in proc report.

to get your desired output you can try this

proc report data = Consumpt nowd split ='\' ;

column PAN ('Year' Year) Sector,High ('Total Consumption' High=stot) ;

define PAN / group noprint ;

define Year / group '' ;

define Sector / across "" format = Sectorid. order = internal ;

define High / "" analysis STYLE(column)={TAGATTR='format:#,##0'} ;

define stot / '' sum STYLE(column)={TAGATTR='format:#,##0'} ;

where put(PAN,Paid.) = "IID" ;

quit ;

This should work.

proc report and across

asishgautam — Fri, 26 Aug 2011 21:08:12 GMT

thank you so much! you have really made my day!