topic Proc Report - Average if? in ODS and Base Reporting

Proc Report - Average if?

FriedEgg — Tue, 08 Nov 2011 22:54:59 GMT

Hi,

Is there a was to compute an average under a certain condition?

For example say I have a modified version of sashelp.class with an additional record where individual has a weight of zero. I want to count this individual into his category, but exclude him from the calculated mean. Here is example code:

proc format;

value myfmt

low-99.999 = 'Light'

100-high = 'Heavy';

quit;

data class;

input (name sex) ($) age height weight;

output;

do until(done);

set sashelp.class end=done;

output;

end;

cards;

FriedEgg M 99 100 0

;

run;

proc report data=class;

column sex weight=status (Sum Mean),weight;

define sex / group;

define status / across format=myfmt. preloadfmt;

define weight / format=comma8.2;

compute after;

line ' ';

line 'Total Class Weight: ' weight.sum comma8.2;

endcomp;

run;

weight Sum Mean

sex Heavy Light weight weight

F 3 6 811.00 90.11

M 6 5 1,089.50 99.05

Total Class Weight: 1,900.50

Desired Output:

e Weight Sum Mean

x Heavy Light Weight Weight

F 3 6 811.00 90.11

M 6 5 1,089.50 108.95

Total Class Weight: 1,900.50

Proc Report - Average if?

Ksharp — Wed, 09 Nov 2011 08:27:03 GMT

Sure. Of course.

You need to make a weight variable to exclude this obs.

proc format;
value myfmt
  low-99.999 = 'Light'
  100-high = 'Heavy';
quit;

 

 

data class;
input (name sex) ($) age height weight;
flag=0;
output;
do until(done);
  set sashelp.class end=done; flag=1;
  output;
end;
cards;
FriedEgg M 99 100 0
;
run;

 

 

proc report data=class nowd;
column sex weight=status (Sum Mean),weight;
weight flag;
define sex / group;
define status / across format=myfmt. preloadfmt;
define weight / format=comma8.2;
compute after;
  line ' ';
  line 'Total Class Weight: ' weight.sum comma8.2;
endcomp;
run;

Ksharp

Proc Report - Average if?

FriedEgg — Wed, 09 Nov 2011 17:51:54 GMT

Thanks Ksharp,

Reporting procedures are my bane.

Proc Report - Average if?

Ksharp — Thu, 10 Nov 2011 02:16:52 GMT

En. Yes. There is lots of thing you need to learn in proc report.

Actually I also spend lots of time to learn this proc which is more complicated than I imaged.

But Here. I will Thank Arthur.Carpenter who wrote a book about it which makes me to learn easily.

It is long time not seeing him here.

Ksharp