topic Re: ODS Data Step Object in ODS and Base Reporting

ODS Data Step Object

JackHamilton — Wed, 15 Mar 2006 18:17:23 GMT

I wonder how many people use the ODS data step object. I know it's experimental, but lots of people use experimental features.

An enhancement I'd like: the ability to directly address table cells, instead of having to figure out where everything is going to go, and then writing it sequentially.

One way to specify it: add ROWS and COLUMNS parameters to TABLE_START, then ROW and COLUMN to FORMAT_CELL and CELL_START.

Hmm, what if I want to get to a nested table from the outer table, or to the outer table from a nested table? I guess htat would be hard.

I guess I could set up a big mess of arrays, write my data there, and then at the end go through the arrays and make the ODS calls, but I'd prefer something a bit more built in.

The specific application I'm thinking about is the ability to build a spreadsheet, filling out cells one at a time.

Re: ODS Data Step Object

David_SAS — Wed, 15 Mar 2006 20:07:10 GMT

Jack,

The data step object integrates the DATA step with ODS' document model,
which includes a table model. ODS' table model is based on the HTML table
model, which is a table-row-cell model. ODS' table model implementation
doesn't support the kind of random access you're describing.

Tables and spreadsheets are fundamentally different things.

Thanks for experimenting with the data step object.

-- David Kelley, SAS

Re: ODS Data Step Object

deleted_user — Wed, 22 Mar 2006 16:46:47 GMT

I appreciate the elegance of the HTML-like cell-addressable approach to building table reports provided by the ODS Data Step Object. As I can do in HTML, I am trying to stack 2 cells in column 2 to complete a ROW_SPAN. Here is a picture of my intent.

row1:col1 row1:col2 row1:col3
row2:col2

In the following code, I want util2 to stack under util1.

obj.ROW_START();
obj.FORMAT_CELL(TEXT: utilgrp,ROW_SPAN : 2);
obj.FORMAT_CELL(TEXT: util1);
obj.FORMAT_CELL(TEXT: cpmpm,ROW_SPAN : 2);
obj.ROW_END();

obj.ROW_START();
obj.FORMAT_CELL(TEXT: util2);
obj.ROW_END();

Here is what I get.

row1:col1 row1:col2 row1:col3
row2:col1 null null

Re: ODS Data Step Object

DanO_sas_com — Wed, 22 Mar 2006 17:53:36 GMT

ods pdf file="test.pdf";
data _null_;
dcl odsout obj();

obj.table_start();
obj.row_start();
obj.format_cell( text: "utilgrp",
row_span: 2 );
obj.format_cell( text: "util1" );
obj.format_cell( text: "cmppm",
row_span: 2 );
obj.row_end();

obj.row_start();
obj.format_cell( text: "util2" );
obj.row_end();
obj.table_end();

obj.delete();
run;

ods pdf close;

The above pgm produced something similar to the following diagram at v9.2 and v9.1.3sp4.

Forgive the formating it does not want to retain my spacing.

----------------------------
| utilgrp | util1 | cmppm |
| | util2 | |
----------------------------

Is this what you want?
What release are you using?

Re: ODS Data Step Object

David_SAS — Wed, 22 Mar 2006 18:22:41 GMT

Although it doesn't appear to be documented in the Help, the forum software supports preformatted text. All you have to do is enclose the text in bracketed pre and /pre tags. Here's what I think Dan wished to express:
[pre]
----------------------------
| utilgrp | util1 | cmppm |
| | util2 | |
----------------------------
[/pre]
-- David Kelley, SAS

Re: ODS Data Step Object

deleted_user — Wed, 22 Mar 2006 19:31:52 GMT

Dan,

Yes, this is what I want. We are running SAS 9.1.3 Service Pack 3. Do I need SP4 to make this work?

Regards,

Dwight

Re: ODS Data Step Object

David_SAS — Wed, 22 Mar 2006 19:48:54 GMT

I expect that SP3 works the same as SP4.

-- David Kelley, SAS

Re: ODS Data Step Object

deleted_user — Wed, 22 Mar 2006 21:39:36 GMT

Sorry if I jump in like this, but how do I access documentation on the ODS data step object? I searched for it at the SAS 9.1 Online documentation at http://support.sas.com/onlinedoc/913, but couldn't find anything.
Furthermore, under the path Base SAS -> SAS Language Concepts -> Data Step Concepts -> Using DATA Step Component Objects, the only objects listed as available in a data step are the Hash object and the Hash Iterator object.
Thanks

Message was edited by: DanielMastropietro at Mar 22, 2006 4:40 PM
Message was edited by: DanielMastropietro at Mar 22, 2006 6:44 PM

Re: ODS Data Step Object

David_SAS — Thu, 23 Mar 2006 02:40:37 GMT

Daniel,

Here is some documentation:

http://support.sas.com/rnd/base/topics/datastep/dsobject/

-- David Kelley, SAS

Re: ODS Data Step Object

DanO_sas_com — Thu, 23 Mar 2006 14:09:25 GMT

Dwight,

It appears to work at Service Pack 3 for me as well.
Can you confirm with the test pgm that I provided?

thanks,
Dan

Re: ODS Data Step Object

deleted_user — Thu, 30 Mar 2006 21:05:56 GMT

Dan,

Your example works as you expected on our SP3. I will retry this approach on my code and let you know.

Re: ODS Data Step Object

deleted_user — Thu, 30 Mar 2006 21:19:00 GMT

This code joins the 2 FORMAT_TEXT strings above the table.
How can I get the strings on separate lines?

IF FIRST.type THEN DO;
obj.FORMAT_TEXT(TEXT: CATX(' ','Normative Comparison Summary for',type));
END;

IF FIRST.frstincr THEN DO;
obj.FORMAT_TEXT(TEXT: time);
END;

obj.TABLE_START();
obj.ROW_START(TYPE: 'HEADER');
obj.FORMAT_CELL(TEXT: ' ');
obj.FORMAT_CELL(TEXT: 'Avg. LOS');
obj.FORMAT_CELL(TEXT: 'Admits/1,000');
obj.FORMAT_CELL(TEXT: 'Scripts/Member');
obj.ROW_END();

obj.ROW_START();
obj.FORMAT_CELL(TEXT: 'Account');
obj.FORMAT_CELL(TEXT: PUT(avglos ,7.2));
obj.FORMAT_CELL(TEXT: PUT(admthou,7.2));
obj.FORMAT_CELL(TEXT: PUT(rx_util,7.2));
obj.ROW_END();
obj.TABLE_END();

Re: ODS Data Step Object

deleted_user — Tue, 04 Apr 2006 15:31:54 GMT

I think I discovered my problem with ROWSPAN: I was using a character argument instead of numeric. Whoops! Thanks for your assistance.

Re: ODS Data Step Object

deleted_user — Tue, 04 Apr 2006 19:47:19 GMT

How can I replicate the behavior of the following 2-part TITLE statement using the TITLE() method?

title j=c 'Main Title' j=r "DATE: %SYSFUNC(TODAY(),MMDDYY10.)";
proc print data=sashelp.class;
run;

Re: ODS Data Step Object

DanO_sas_com — Tue, 04 Apr 2006 20:26:20 GMT

ods listing close;

/* Try pdf & rtf as well */
%let dest =html;
options nodate nonumber;
ods &dest file="test.&dest";

title j=c 'Main Title' j=r "DATE: %SYSFUNC(TODAY(),MMDDYY10.)";
proc print data=sashelp.class;
run;

title;
data _null_;
set sashelp.class end=eof;
if _n_ = 1 then do;
dcl odsout obj();
obj.title(text: "Main Title",
overrides: "width=5.5in just=right",
text: "Date %SYSFUNC(TODAY(), MMDDYY10.)",
overrides: "width=4.5in just=right");

obj.table_start();
obj.row_start(type: "header");
obj.format_cell(text: "Name");
obj.format_cell(text: "Sex" );
obj.row_end();
end;

obj.row_start();
obj.format_cell(text: name);
obj.format_cell(text: sex);
obj.row_end();

put eof=;

if eof = 1 then do;
obj.table_end();
obj.delete();
end;
run;

ods &dest close;

Re: ODS Data Step Object

deleted_user — Tue, 04 Apr 2006 21:07:53 GMT

Dan,

Thanks for the rapid response. Unfortunately, running your code on my SAS SP3 fails to show the "Main Title" and centers the date above the body table. DO I have to wait for SP4+ or is there a way with SP3?

Thanks,

Dwight

Re: ODS Data Step Object

DanO_sas_com — Wed, 05 Apr 2006 20:31:02 GMT

Dwight,

You are correct. It does work at v9.2, but that does not help you at all. I tried a couple of other approaches, and could not get it to work in V9.13sp*.

Sorry,
Dan

Re: ODS Data Step Object

deleted_user — Wed, 07 Jun 2006 18:26:22 GMT

Dan,

I really appreciate the ODS Data Step Object approach to report writing. It promises a high degree of layout control while providing significant layout intelligence to handle minutae automagically. When can we expect it to go production?

Dwight

Re: ODS Data Step Object

DanO_sas_com — Wed, 07 Jun 2006 19:02:12 GMT

Dwight,

We expect that the ODS Data Step Object code will be production in the v9.2 timeframe with one minor limitation. The LAYOUT/REGION methods will still remain experimental. Despite the fact that these 2 methods will remain experimental a significant amount of work has been done to stabalize our Layout capabilities throughout ODS. We hope to have some very exciting LAYOUT capabilities for you to experiment with in v9.2, and as always will look forward to your valuable insight to further enhance our offerings.

thanks,
Dan