topic Re: How to customize the background color for a row using Excelxp in a proc rep in ODS and Base Reporting

How to customize the background color for a row using Excelxp in a proc rep

Inp — Wed, 27 Oct 2010 18:49:37 GMT

Hi Dear,

Here is my coding. I want to add background colour blue for the row when the value of x = 'b' . My coding seems running without error but I don't see the background color. Can you please let me know how I do it. I am using SAS 9.2 and on Windows XP.

data temp1;
input @1 x $1. @2 y $1. @3 z $1.;
cards;
abc
abd
abf
abc
abw
acw
acq
bcd
;
run;

ODS LISTING CLOSE;
ods tagsets.excelXP path='c:\' file="mytest.XLS" style=newstyle rs= none;

TITLE " my title " ;
ods tagsets.excelXP options(
Sheet_Name="mytes"
Absolute_Column_Width='30,30,10'
);
run;

proc report data=temp1 nowd ;
column x y z;
define x / order ' x';
define y / order 'y';
define z / 'z';

compute after x;
if x='b' then ;
call define (_row_ ,'style','style={background=blue}');
endcomp;
run;

ods _all_ close;
ods LISTING;

Re: How to customize the background color for a row using Excelxp in a proc rep

Tim_SAS — Wed, 27 Oct 2010 19:03:30 GMT

Use

[pre]
compute x;
[/pre]
instead of

[pre]
compute after x;
[/pre]
The latter statement alters the row after the row when the value of x = 'b', and there is no such row.

Re: How to customize the background color for a row using Excelxp in a proc rep

Inp — Thu, 28 Oct 2010 01:27:13 GMT

Hi Tim
When I put compute x, it put color(background blue) for all rows. But my interest in only the row when x='b'. Thanks a lot for your help.

Thanks

Inp

Re: How to customize the background color for a row using Excelxp in a proc rep

Cynthia_sas — Thu, 28 Oct 2010 02:57:54 GMT

Hi:
I would recommend that you review your IF statement syntax. This code:
[pre]
compute x;
if x='b' then ;
call define (_row_ ,'style','style={background=blue}');
endcomp;
[/pre]

specifically
[pre]
if x='b' then;
[/pre]

is incorrect. It should be either (no semi-colon after 'then'):
[pre]
compute x;
if x='b' then
call define (_row_ ,'style','style={background=blue}');
endcomp;
[/pre]

OR (use do/end construction with the IF)

[pre]
compute x;
if x='b' then do;
call define (_row_ ,'style','style={background=blue}');
end;
endcomp;
[/pre]

cynthia