topic selected summarizations on PROC REPORT in ODS and Base Reporting

selected summarizations on PROC REPORT

milts — Tue, 13 Dec 2011 02:11:23 GMT

Hi,

I have this sample dataset. What I want to happen on my proc report is that I on the row for the totals, I only want a value displayed for the column two and column one should not have a summary value. Is this possible? Please see script below and current and desired results. Thanks!

data test;

input nm $ one two;

datalines;

one 1 10

two 2 20

three 3 30

;

proc report data=test;

column nm one two ;

define nm / display;

define one / analysis sum;

define two / analysis sum;

rbreak after / summarize;

compute after;

if _break_ = '_RBREAK_' then do;

nm = 'Total';

end;

endcomp;

run;

quit;

Current Output

nm	one	two
one	1	10
two	2	20
three	3	30
total	6	60

Desired Output

nm	one	two
one	1	10
two	2	20
three	3	30
total		60

selected summarizations on PROC REPORT

Cynthia_sas — Tue, 13 Dec 2011 05:16:00 GMT

Hi:

If variable ONE has a usage of SUM ANALYSIS, it will be summarized during break processing. If variable ONE has a usage of DISPLAY, it will NOT be summarized at break processing. This is a simple fix and understanding the difference between DISPLAY and SUM is fundamental to how PROC REPORT decides which columns get summarized or not.

cynthia

selected summarizations on PROC REPORT

Ksharp — Tue, 13 Dec 2011 08:21:13 GMT

Sure. Of course.

data test;
    input nm $ one two;
    datalines;
one 1 10
two 2 20
three 3 30
;
run;

 
option missing='';
proc report data=test  nowd;
    column nm one two ;
    define nm / display;
    define one / analysis sum;
    define two / analysis sum;
    rbreak after / summarize;
    compute after;
        if _break_ = '_RBREAK_' then do;
            nm = 'Total'; call missing(one.sum);
        end;
    endcomp;
run;

Ksharp