topic Re: ODS PDF and PROC REPORT - how can I combine columns without an over-arching combo? in ODS and Base Reporting

ODS PDF and PROC REPORT - how can I combine columns without an over-arching combo?

SASGeek — Mon, 13 Apr 2026 18:37:37 GMT

Hi there,

I'm wondering if what I want to do in ODS with PROC REPORT is possible. Currently the following code works but as expected -- the % Yes column header spans the two columns, but one row higher than I want it to. Any way to work around that?

Thanks

data uc1;

INPUT DIVISION $ No pct_n_total Yes pct_y_total;

LENGTH DIVISION $ 1 No 8 pct_n_total 8 Yes 8 pct_y_total 8;

FORMAT

DIVISION $CHAR1.

No COMMA12.2

pct_n_total COMMA12.2

Yes COMMA12.2

pct_y_total COMMA12.2;

datalines;

a 79354 0.4685 90034 0.5315

b 94541 0.6260 56479 0.3740

c 10635 0.1183 79255 0.8817

d 40340 0.4720 45118 0.5280

;

run;

ods pdf file = "/home/zkurzej/file.pdf" style=smaller STARTPAGE=NEVER;

footnote j=c "Page ^{thispage} of ^{lastpage}";

ods layout absolute;

ods region x=0.00in y=.75in width=3.38in height=6.8in;

proc report data= uc1 nowd missing split= '~'

style(report) = [cellspacing = 2 cellpadding =4 rules=groups frame=hsides]

style(header) = [fontsize=6pt vjust = top]

style(column)=[fontsize=6pt];

Title "uc1";

column DIVISION

pct_n_total

Yes

('% Yes' pct_y_total bar);

define DIVISION / 'DIVISION';

define No / 'No' format = comma15.0;

define pct_n_total / '% No' format = percent10.2;

define Yes / '% Yes' format = comma15.0;

define pct_y_total / '% Yes' format = percent10.2

style(column) = [borderrightcolor=black borderrightwidth=.5pt];

define bar / ' ' style(column) = [font_size=4pt

fontfamily='Courier New'

vjust=middle

just=left cellpadding=0];

compute bar / char length = 1000;

barsize = round(pct_y_total.sum*50);

if barsize gt 0 then

do;

bar = repeat('^{unicode 2588}', barsize);

call define ('_c6_','style','style={foreground = red}');

end;

endcomp;

run;

ods layout end;

ods pdf close;

Re: ODS PDF and PROC REPORT - how can I combine columns without an over-arching combo?

ahmedalattar — Mon, 13 Apr 2026 20:10:16 GMT

@SASGeek

Try changing the column statement to this

column ('DIVISION' DIVISION) ('No' No) ('% No' pct_n_total) ('Yes' Yes) ('% Yes' pct_y_total bar);

Replace the columns labels with '' (missing) in the define statements, such as

define DIVISION / '' ;
define No / '' format = comma15.0;
define pct_n_total / '' format = percent7.3;
define Yes / '' format = comma15.0;
define pct_y_total / '' format = percent7.3
style(column) = [borderrightcolor=black borderrightwidth=.5pt];

define bar / '' style(column) = [font_size=4pt
fontfamily='Courier New' 
vjust=middle 
just=left cellpadding=0];

This should give you what you are looking for

Re: ODS PDF and PROC REPORT - how can I combine columns without an over-arching combo?

SASGeek — Thu, 16 Apr 2026 15:05:42 GMT

Good idea. Thanks. I'll give it a try!

Re: ODS PDF and PROC REPORT - how can I combine columns without an over-arching combo?

klt4xc — Mon, 04 May 2026 11:52:43 GMT

thanks for the information!