topic Re: To create rtf file reading 2 PNG files with different page number and titles in ODS and Base Reporting

To create rtf file reading 2 PNG files with different page number and titles

Chetan302 — Mon, 13 Nov 2023 11:46:36 GMT

I have created rtf file reading 2 PNG files displayed separately in two pages using ods text statement but with same title and page number.
Need to have different title and page number for both rtf pages.
code I am using looks like:-
%let _std_ods_type = rtf;

title 1 'page (1 of 2)';

title3 "Treatment 1";

ods rtf file = 'path/trackerfile_name.outpt_reference' style = custom startpage = never;

ods text = 'path/file_name1.png' ;

title 1 'page (2 of 2)';

title3 "Treatment 2";

ods text = 'path/file_name2.png' ;

ods rtf close;

This code is giving titles defined first in both pages.

If I pass the code in simple loop then getting titles defined at last in both pages.

Re: To create rtf file reading 2 PNG files with different page number and titles

Bari_sas — Mon, 13 Nov 2023 20:48:15 GMT

While you see the images on separate pages, the ODS RTF TEXT= statement will not force a page break / step boundary, which is what is required for the title to change. I suggest using PROC ODSTEXT instead. I have success with the following code in SAS 9.4m8. Please let me know your results.

options nodate nonumber;
ODS LISTING GPATH = "/tmp";
ods graphics on / imagename="first" imagefmt=png border=off;

proc sgplot data=sashelp.class;
scatter x=height y=weight;
ellipse x=height y=weight;
run;
ods graphics on / imagename="second" imagefmt=png border=off;
proc sgplot data=sashelp.cars;
hbox weight / category=origin;
run;
ods listing close;

ods escapechar="^";
%let _std_ods_type = rtf;

title1 'Page ^{thispage} of ^{lastpage}';
title3 "Treatment 1";
ods rtf file = '/tmp/file.rtf' ;

proc odstext;
P '^S={outputwidth=100% preimage="/tmp/first.png"}';
run;


title1 'Page ^{thispage} of ^{lastpage}';
title3 "Treatment 2";

proc odstext;
P '^S={outputwidth=100% preimage="/tmp/second.png"}';
run;
ods rtf close;

Here's a snippet of my titles from each page:

Re: To create rtf file reading 2 PNG files with different page number and titles

ballardw — Mon, 13 Nov 2023 21:07:14 GMT

What happens if you remove the STARTPAGE=NEVER from the ODS Rtf statement?

Re: To create rtf file reading 2 PNG files with different page number and titles

Chetan302 — Wed, 15 Nov 2023 12:39:34 GMT

Thank you so much for your prompt reply. This work around works for me

Re: To create rtf file reading 2 PNG files with different page number and titles

Chetan302 — Wed, 15 Nov 2023 12:41:25 GMT

Thank you so much for your valuable inputs. I have tried by removing it and by changing STARTPAGE options but no luck.

Re: To create rtf file reading 2 PNG files with different page number and titles

Ksharp — Thu, 16 Nov 2023 05:29:39 GMT

options nodate nonumber;
ods escapechar="^";
title1 'Page ^{thispage} of ^{lastpage}';
title3 "Treatment 1";
ods rtf file = 'c:\temp\a\file.rtf'  nogtitle dpi=300 ;

ods graphics on / border=off outputfmt=png;
proc sgplot data=sashelp.class;
scatter x=height y=weight;
ellipse x=height y=weight;
run;

/*title1 'Page ^{thispage} of ^{lastpage}';*/
title3 "Treatment 2";
ods graphics on / border=off  outputfmt=png;
proc sgplot data=sashelp.cars;
hbox weight / category=origin;
run;
ods rtf close;