How to have two title statements on the same line inside the ODS Statement?

diwashsapkota — Mon, 16 Oct 2023 09:29:20 GMT

I want to display the title2 and title3 on the same line, with title2 left aligned and title3 right-aligned inside the header section of my ods rtf file. I have the following code above my PROC REPORT Statement:

proc template;

%** Courier 9pt **;

define style styles.ods_9pt;

parent=styles.rtf;

replace fonts/ 'TitleFont2'=("Courier New", 9pt) 'TitleFont'=("Courier New",

9pt) 'FootnoteFont'=("Courier New", 9pt) 'StrongFont'=("Courier New", 9pt)

'EmphasisFont'=("Courier New", 9pt) 'FixedEmphasisFont'=("Courier New", 9pt)

'FixedStrongFont'=("Courier New", 9pt) 'FixedHeadingFont'=("Courier New",

9pt) 'BatchFixedFont'=("Courier New", 9pt) 'FixedFont'=("Courier New", 9pt)

'headingEmphasisFont'=("Courier New", 9pt) 'headingFont'=("Courier New",

9pt) 'docFont'=("Courier New", 9pt);

replace document from container / asis=on protectspecialchars=off;

replace SystemFooter from TitlesAndFooters / asis=on protectspecialchars=on

font=Fonts('FootnoteFont');

replace systemtitle from titlesandfooters/ asis=on protectspecialchars=off;

replace body from document / asis=on;

replace color_list "Colors used in the default style" / 'link'=blue

'bgH'=white 'fg'=black 'bg'=white;

replace Table from output / Background=_UNDEF_ cellpadding=0pt Rules=groups

Frame=hsides;

style Header from Header / Background=_undef_;

style Rowheader from Rowheader / Background=_undef_;

replace pageno from titlesandfooters/ Foreground=white;

end;

run;

ods rtf file='/home/u63366981/01_adam/results/teaetg.rtf' style=styles.ods_9pt;

ods rtf startpage=now;

ods escapechar='#';

title1 color="black" justify=left "Protocol:CDISCPILOT01";

title2 color="black" justify=left "Population:Safety";

title3 color="black" justify=right 'Page #{thispage} of #{lastpage}';

title4 color="black" justify=center bold "Template 13";

title5 color="black" justify=center

"Incident of Treatment Emergent Adverse Events by Treatment Group";

options center date number;

Re: How to have two title statements on the same line inside the ODS Statement?

PaigeMiller — Mon, 16 Oct 2023 10:55:19 GMT

Try this (UNTESTED)

title2 color="black" justify=left "Population:Safety" justify=right 'Page #{thispage} of #{lastpage}';

Re: How to have two title statements on the same line inside the ODS Statement?

diwashsapkota — Mon, 16 Oct 2023 13:10:54 GMT

Thank you, it worked!

topic How to have two title statements on the same line inside the ODS Statement? in ODS and Base Reporting

How to have two title statements on the same line inside the ODS Statement?

Re: How to have two title statements on the same line inside the ODS Statement?

Re: How to have two title statements on the same line inside the ODS Statement?