topic Re: How to add page border to ODS RTF file in ODS and Base Reporting

How to add page border to ODS RTF file

LUISBARTHOLO — Tue, 20 Dec 2022 20:10:20 GMT

Hi all!

I just wanted to add pageborders in the output.

Something like this:

Here is the code:

ods RTF startpage=no file="c:\sas\sas.docx" NOGTITLE NOGFOOTNOTE style=word;
options nonumber nodate;

title PAGE BORDER;
footnote;

ODS RTF startpage=now TEXT="{\pard\b\qc {PAGE1} \par}"; RUN;

proc odstext;
p "REPORT:" /style=[fontweight=bold textalign=c fontsize=20pt fontfamily=Arial];
run;

proc report data=sashelp.cars contents="Honda Cars";
where Make="Honda";
column ("Car" make model) ("Cost" msrp invoice)
("Fuel Efficiency" mpg_city mpg_highway);
run;

ODS RTF startpage=now TEXT="{\pard\b\qc {PAGE2} \par}"; RUN;

proc report data=sashelp.cars nowd OUT=QUARTILES;
column origin type msrp msrp=msrp2 msrp=msrp3 msrp=msrp4 msrp=msrp5;
define origin / group;
define type / group;
define msrp / p25;
define msrp2 / median;
define msrp3 / p75;
define msrp4 / min;
define msrp5 / max;
run;

ods RTF close;

Re: How to add page border to ODS RTF file

fja — Sun, 25 Dec 2022 12:28:48 GMT

Hello there and Merry Christmas!

Is it the frames around the page area you are after or is it some sort of margin.

And what output type are you after? ... as your pictures of the output already contain frames. Running your code on my system does include page frames in the resulting rtf, though.

Cheers

FJa

Re: How to add page border to ODS RTF file

LUISBARTHOLO — Fri, 17 Feb 2023 19:40:08 GMT

This is what i get with the code (no boarders):

This is what I would like (with boarders):

Re: How to add page border to ODS RTF file

Kathryn_SAS — Wed, 22 Feb 2023 16:10:27 GMT

The following style template adds a visible top and bottom page margin, but I have not found a way to add a left or right margin. This also adds a blank Footnote.

proc template;
 define style styles.test;
 parent=styles.rtf;
 class systemtitle /
  bordertopcolor=black
  bordertopwidth=2pt;
 class systemfooter /
  borderbottomcolor=black
  borderbottomwidth=2pt;
 class body /
  frame=box;
 end;
run;

ods _all_ close;
ods RTF startpage=no file="c:\temp\test.rtf" NOGTITLE NOGFOOTNOTE 
 style=styles.test;
options nonumber nodate;

title PAGE BORDER;
footnote ' ';

ODS RTF startpage=now TEXT="{\pard\b\qc {PAGE1} \par}"; RUN;

proc odstext;
p "REPORT:" /style=[fontweight=bold textalign=c fontsize=20pt fontfamily=Arial];
run;

proc report data=sashelp.cars contents="Honda Cars";
where Make="Honda";
column ("Car" make model) ("Cost" msrp invoice)
("Fuel Efficiency" mpg_city mpg_highway);
run;

ODS RTF startpage=now TEXT="{\pard\b\qc {PAGE2} \par}"; RUN;

proc report data=sashelp.cars nowd OUT=QUARTILES;
column origin type msrp msrp=msrp2 msrp=msrp3 msrp=msrp4 msrp=msrp5;
define origin / group;
define type / group;
define msrp / p25;
define msrp2 / median;
define msrp3 / p75;
define msrp4 / min;
define msrp5 / max;
run;

ods RTF close;

Re: How to add page border to ODS RTF file

Kathryn_SAS — Wed, 22 Mar 2023 17:28:47 GMT

I also found a link to this SAS Note:

52068 - Place a border around the perimeter of the page in the ODS RTF destination (sas.com)

Re: How to add page border to ODS RTF file

LUISBARTHOLO — Tue, 28 Mar 2023 17:09:26 GMT

Thank you !!

Re: How to add page border to ODS RTF file

LUISBARTHOLO — Tue, 28 Mar 2023 17:10:06 GMT

Thank you very much!!