topic Re: ods excel and borders - do you have a smarter way of adding those borders? in ODS and Base Reporting

ods excel and borders - do you have a smarter way of adding those borders?

xxformat_com — Mon, 20 Dec 2021 12:41:09 GMT

Hi,

Given that frame= and rules= don't seem to be taken into account in the ods excel destination, I was wondering whether there would be a smarter ways of of adding the borders than this one:


data class;
   set sashelp.class end=_eof;
   eof=_eof;
run;

ods excel file="&xxtest./reporting/test.xlsx" 
          options(start_at='2,2');

proc report data=class 
           style(column header)=[borderstyle = hidden
                                 borderstyle = hidden]
           style(header)=[bordertopstyle    = solid
                          bordertopcolor    = red
                          borderbottomstyle = solid
                          borderbottomcolor = blue];
    column eof name--height;
    define eof / display noprint;
    compute eof;
        if eof=1 then call define(_row_,'style','style=[borderbottomstyle=solid 
                                                        borderbottomcolor=red]');
    endcomp;
run;

ods excel close;

Re: ods excel and borders - do you have a smarter way of adding those borders?

Ksharp — Mon, 20 Dec 2021 14:42:16 GMT

ods excel file="c:\temp\test.xlsx"  
          options(start_at='2,2');

proc report data=sashelp.class nowd 
style(column)={
 borderleftcolor=white borderleftwidth=2
 borderrightcolor=white borderrightwidth=2
 bordertopcolor=white bordertopwidth=2 
 borderbottomcolor=white borderbottomwidth=2 }
style(header)={
 borderleftcolor=cxEDF2F9 borderleftwidth=2
 borderrightcolor=cxEDF2F9 borderrightwidth=2
 bordertopcolor=black bordertopwidth=2 
 borderbottomcolor=black borderbottomwidth=2 }
;
compute weight;
if name='William' then call define(_row_,'style','style={
borderbottomcolor=black borderbottomwidth=2
}');
endcomp;
run;

ods excel close;