topic Re: Controlling Borders in Header Using PROC REPORT and ODS RTF in ODS and Base Reporting

Controlling Borders in Header Using PROC REPORT and ODS RTF

RS-1 — Fri, 18 Jan 2019 00:57:20 GMT

Hello:

I'm looking for a way to control the borders in an RTF output. Currently the spanned columns underline extends the width of the table. I'd like that to only cross the data columns (see attached).

Code below:

/** RTF **/
ods listing close;
ods rtf file="test1.rtf" style=basic;

%macro prpt;

proc report data=final split="~" nowindows missing
style(report)={outputwidth=100% just=left}
style(header)={asis=on bordertopwidth=0.24pt bordertopcolor=black font_weight=bold}
;

columns pageno paramn_new trt01an linlabel
("Worst Postbaseline Toxicity Grade^{super a}" value0 value1 value2 value3 value4 value5);

define pageno / order order=internal noprint;
define paramn_new / order order=internal noprint;
define trt01an / order order=internal noprint;

define linlabel / " "       style(column)={cellwidth=2.6in just=l};
define value0   / "Grade 0" style(column)={cellwidth=1.0in just=c} style(header)={just=c font_weight=bold};
define value1   / "Grade 1" style(column)={cellwidth=1.0in just=c} style(header)={just=c font_weight=bold};
define value2   / "Grade 2" style(column)={cellwidth=1.0in just=c} style(header)={just=c font_weight=bold};
define value3   / "Grade 3" style(column)={cellwidth=1.0in just=c} style(header)={just=c font_weight=bold};
define value4   / "Grade 4" style(column)={cellwidth=1.0in just=c} style(header)={just=c font_weight=bold};
define value5   / "Missing" style(column)={cellwidth=1.0in just=c} style(header)={just=c font_weight=bold};

break after pageno / page ;

%if (&nobs eq 0) %then %do;
compute after paramn_new;
  line @2 'No Lab data. ';
endcomp;
    %end;
%else %do;
compute after paramn_new;
  line @2 ' ';
endcomp;

compute linlabel;
    if (indexw(linlabel,'m')=1) then do;
   linlabel=substr(linlabel,3,length(linlabel));
        call define(_col_, "style", "style=[leftmargin=25]");
    call define('_c1_',"style","style=[background=red]");
  end;
endcomp;
    %end;

run;
%mend prpt;
%prpt;

ods rtf close;
ods listing;

Re: Controlling Borders in Header Using PROC REPORT and ODS RTF

Cynthia_sas — Fri, 18 Jan 2019 02:25:31 GMT

Hi:
Without data, no one can run your code without spending the time to figure out the structure of your WORK.FINAL data set. And since you have so many NOPRINT items, it's hard to figure out how you created them to even attempt to make fake data.
Cynthia

Re: Controlling Borders in Header Using PROC REPORT and ODS RTF

RS-1 — Mon, 21 Jan 2019 06:50:50 GMT

Indeed. Fortunately I figured out a solution. Force a blank header for column 1 and set the bottom border to white, which effectively hides it.

columns pageno paramn_new trt01an

('^S={borderbottomcolor=white}' linlabel)

("Worst Postbaseline Toxicity Grade^{super a}" value0 value1 value2 value3 value4 value5);

Re: Controlling Borders in Header Using PROC REPORT and ODS RTF

derekmor54 — Thu, 23 Jul 2020 19:34:20 GMT

There is another solution. You can remove the border by using the BORDERBOTTOMSTYLE=HIDDEN. It's a small difference between setting the border to the background color, and hiding the border, but the HIDDEN value of the BORDER()STYLE attribute can remove borders in individual cells without blotting out the gridlines at the junction of your cells.