proc tabulate - remove subtotal heading (keeping top header)

GertNissen — Wed, 06 May 2020 14:32:59 GMT

Is there a way to remove only the repeating sub headings [red arrow] - (while still keeping the first heading [blue arrow])

Sample code to produce the output above

proc tabulate data=sashelp.class;
class age name;
var Weight;

table age*(name all='all name'*[style=[background=lightblue]]) all='all age', Weight;
run;

To get something like this with only a top header and no header for each subtotal.

Re: proc tabulate - remove subtotal heading (keeping top header)

Cynthia_sas — Wed, 06 May 2020 14:58:54 GMT

Hi:

The best you can do with TABULATE is to move the row headers (Age/Name) up into the Box on the left side of the top of the table.

You might like the look and feel of PROC REPORT better:

Here's the code for PROC REPORT vs the BOX approach with TABULATE:

proc tabulate data=sashelp.class;
class age name;
var Weight;
table age=' '*(name=' ' all='all name'*[style=[background=lightblue]]) all='all age', 
      Weight / box='Age and Name';
run;

proc report data=sashelp.class
  style(summary)=Header;
  column age name weight;
  define age / order style(column)=Header;
  define name / order style(column)=Header;
  define weight / sum;
  break after age/summarize;
  compute after age;
    name='Name Tot';
	line ' ';
  endcomp;
run;

Cynthia

topic Re: proc tabulate - remove subtotal heading (keeping top header) in ODS and Base Reporting

proc tabulate - remove subtotal heading (keeping top header)

Re: proc tabulate - remove subtotal heading (keeping top header)