topic Re: Proc Report compute difference between values of across variable in ODS and Base Reporting

Proc Report compute difference between values of across variable

Patrick — Sun, 15 Dec 2019 00:52:40 GMT

Hi all,

Using Proc Report I am trying to calculate the difference between the values of two cells under an across variable. Even after reading through some of the discussions and whitepapers I still can't get this to work.

Using below sample data the desired result in the first row under column diff_X1X2 is 1 ( 3-2) and -0.666.. in the 2nd row.

I do know that the value in categorical variable catX is either 'X1' or 'X2'

data have;
  infile datalines truncover dlm=',' dsd;
  input catX $ catY $ value;
  datalines;
X1,Y1,2
X1,Y1,4
X1,Y2,1
X1,Y2,3
X2,Y1,2
X2,Y2,2
X2,Y2,3
X2,Y2,3
;

proc report data=have nowd;
  column  catY (catX, value diff_X1X2;  
  define catY  / group ;
  define catX  / group across;
  define value / analysis mean;
  define diff_X1X2  / computed;
  compute diff_X1X2;
    diff_X1X2=_c_1-_c_2;
  endcomp;
run;

Re: Proc Report compute difference between values of across variable

PaigeMiller — Sun, 15 Dec 2019 00:55:10 GMT

I think you need to refer to these columns as _C1_ and _C2_

Re: Proc Report compute difference between values of across variable

SASKiwi — Sun, 15 Dec 2019 01:03:10 GMT

I suspect CatY may also count as a column so it could be _C2_ and _C3_.

Re: Proc Report compute difference between values of across variable

PaigeMiller — Sun, 15 Dec 2019 01:08:44 GMT

Yep that's it @SASKiwi

Re: Proc Report compute difference between values of across variable

Ksharp — Sun, 15 Dec 2019 10:10:44 GMT

As SASKiWI said ,it _c2_ and _c3_ , you could check its real name by option OUT= .

data have;
  infile datalines truncover dlm=',' dsd;
  input catX $ catY $ value;
  datalines;
X1,Y1,2
X1,Y1,4
X1,Y2,1
X1,Y2,3
X2,Y1,2
X2,Y2,2
X2,Y2,3
X2,Y2,3
;

proc report data=have nowd out=temp;
  column  catY (catX, value diff_X1X2);  
  define catY  / group ;
  define catX  / group across;
  define value / analysis mean;
  define diff_X1X2  / computed;
  compute diff_X1X2;
    diff_X1X2=_c2_-_c3_;
  endcomp;
run;

Re: Proc Report compute difference between values of across variable

ed_sas_member — Sun, 15 Dec 2019 10:12:22 GMT

proc report data=have nowd;
	column  catY (catX, value diff_X1X2);  
	
	define catY  / group ;
	define catX  / across;
	define value / analysis mean;
	define diff_X1X2  / computed;
 
	compute diff_X1X2;
		diff_X1X2=_c2_-_c3_;
	endcomp;
  
run;