topic Re: Picture format or applicable in ODS and Base Reporting

Picture format or applicable

Doug____ — Thu, 21 Mar 2019 20:33:24 GMT

I need to create/use a format that does the following:

displays dollar amounts $xxxx,xx - > when zero or positive

($xxx,xxx) <-in red when negative

I tried doing picture formats and could not get it to work properly.

Re: Picture format or applicable

Reeza — Thu, 21 Mar 2019 20:39:22 GMT

@Doug____ wrote:

I need to create/use a format that does the following:

displays dollar amounts $xxxx,xx - > when zero or positive

($xxx,xxx) <-in red when negative

I tried doing picture formats and could not get it to work properly.

Can you show what you've tried so far? A picture format is the right approach here. Or you could create custom formats using a function and then use nested formats.

Re: Picture format or applicable

Doug____ — Thu, 21 Mar 2019 20:50:02 GMT

Actually I think I got it about two minutes after posting as follows:

proc format;

picture dollar

0-high = '0,000,009' (prefix = '$')

low-<0 = '0,000,009)' (prefix = '^S={color = red}($');

run;

Re: Picture format or applicable

ballardw — Thu, 21 Mar 2019 21:25:21 GMT

proc format library = work cntlout=work.fmt;
picture negdollar  
low -<0 = '00,000,000,000,009.99)' (prefix='($'  )
0-high  = [dollar21.2]
;
run;

data example;
   input x;
   y= -1*x;
datalines;
1
12
123
1234
12345
123456
1234567
12345678
;
run;

proc print data=example;
  format x y negdollar.;
run;

Re: Picture format or applicable

Ksharp — Fri, 22 Mar 2019 11:27:29 GMT

Use Traffic Light .

data have;
input id x;
cards;
1 10000
2 -10000
;
run;


proc format ;
value fmt
 low-<0='red';
 run;

ods pdf file='c:\temp\x.pdf';

proc report data=have nowd;
column id x;
define id/display;
define x/display style={foreground=fmt.};
run;

ods pdf close;