topic Re: ODS EXCEL: Removing Borders when Outputting LOG in ODS and Base Reporting

ODS EXCEL: Removing Borders when Outputting LOG

pkfamily — Wed, 30 Jan 2019 23:31:49 GMT

Is there a way to remove the border when outputting the log into ODS EXCEL? I'm running SAS 9.4 M4.

Code:

filename test "K:\SAS\logs\log.log";
proc printto log=test new; run;

ODS excel file="K:\SAS\logs\test.xlsx" options(sheet_interval="none");
	proc printto;run;
	proc document name=mydoc(write);
		import textfile=test to logfile;run; 
		replay;run;
	quit;
ODS excel close;

I tried the following styles to no avail as well as the grindlines="no" option.

proc template;
  define style styles.test;
     parent=styles.default;
         style table from table /
            borderwidth=0
            cellspacing=0;
  end;
run;

proc template;
	define style styles.noborder;
		class table /
			borderwidth=0
			rules=none
			frame=void
			cellspacing=0
			background=white;
	end;
run;

Any help is appreciated. Thanks.

Re: ODS EXCEL: Removing Borders when Outputting LOG

ChrisNZ — Fri, 01 Feb 2019 02:49:41 GMT

This works:

filename test "%sysfunc(pathname(WORK))\log.log";
proc printto log=test new; run;
data T; run;
proc printto;run;

ODS excel file="%sysfunc(pathname(WORK))\test.xlsx" options(sheet_interval="none");
data  _null_;
  if _n_ = 1 then do;
    declare odsout ODS();
  end; 
  infile "%sysfunc(pathname(WORK))\log.log";
  input;
  ODS.format_text(data: _infile_); 
run;
ODS excel close;

Re: ODS EXCEL: Removing Borders when Outputting LOG

pkfamily — Mon, 04 Feb 2019 19:51:19 GMT

Thanks for the solution! I'm a bit new to the ODS language but I'm guessing your method reads in a log text file which is then outputted into ODS inside a data step. And the format_text function removes the borders for some reason.

Re: ODS EXCEL: Removing Borders when Outputting LOG

ChrisNZ — Mon, 04 Feb 2019 21:40:12 GMT

I am discovering the ODSOUT object too. It looks very useful.