topic Re: Removing blank space in ODS and Base Reporting

Removing blank space

FLINT — Mon, 28 May 2018 14:17:28 GMT

I am creating CSV file from sas dataset using following code

Data _null_;
set dataset;
File "filename" DLM=',';
if _n_ eq 1 then do
****
****
Put 'A,B,C';
End;
PUt A B C;
run;

Problem is that a blank space is introduced in fileds with null values.

Please help how to avoid that.

Re: Removing blank space

SuryaKiran — Mon, 28 May 2018 14:49:36 GMT

Please provider some sample data and the full code your using or use sample SAS datasets as below. It's something to do with your data or code you have.

Filename out_CSV "\Output\out_file.csv";
Data _null_;
set sashelp.class;
File out_CSV DLM=',';
PUT Name Age Sex Height Weight;
run;

Re: Removing blank space

FLINT — Mon, 28 May 2018 15:06:52 GMT

Surya ,
I am the same code and the data set is like
Column Ais Bank_code
B is PAN_Number
C is party_name
Here The problem is that some of the pan numbers are missing where where blank space is getting populated instead of null

Re: Removing blank space

SuryaKiran — Mon, 28 May 2018 16:12:36 GMT

Instead of writing individual variables, create a string with like delimited and write that string to file.

data have;
set sashelp.class;
If sex="M" then call missing(Sex);
run;
Filename out_CSV "\Output\out_file.csv";
Data _NULL_;
set Have;
File out_CSV DLM=',';
out_Line=CATS(Name,",",Sex,",",Age,",",Height,",",Weight);
PUT out_Line;
run;

Re: Removing blank space

Astounding — Mon, 28 May 2018 16:56:31 GMT

Get rid of the delimiter, and code it yourself:

Data _null_;
set dataset;
File "filename" noprint;
if _n_ eq 1 then do
****
****
Put 'A,B,C';
End;
PUt A +(-1) ',' B +(-1) ',' C;
run;

However, this method runs into trouble when A or B has a format associated with it.

Re: Removing blank space

Tom — Mon, 28 May 2018 17:24:31 GMT

That is what the DSD option on the FILE statement if for.

data have ;
  input a b c ;
cards;
1 2 3
4 . 6
. . 7
;
data _null_;
  set have;
  file log dsd dlm=',';
  put a b c;
run;

Results

1,2,3
4,,6
,,7

Re: Removing blank space

Reeza — Mon, 28 May 2018 20:47:10 GMT

If there's nothing particularly special about your export, any reason to not use PROC EXPORT?

proc export data=sashelp.class outfile=filename dbms=csv replace;run;

@FLINT wrote:
I am creating CSV file from sas dataset using following code

Data _null_;
set dataset;
File "filename" DLM=',';
if _n_ eq 1 then do
****
****
Put 'A,B,C';
End;
PUt A B C;
run;

Problem is that a blank space is introduced in fileds with null values.

Please help how to avoid that.

Re: Removing blank space

FLINT — Tue, 29 May 2018 05:12:15 GMT

Bingo..it worked wonders....thanks

Re: Removing blank space

FLINT — Tue, 29 May 2018 05:39:46 GMT

@Reeza I m not using export cause I have to use macro variable in the header of the CSV file