topic Re: Call define in proc report in ODS and Base Reporting

Call define in proc report

Ajayvit — Sat, 05 May 2018 08:13:16 GMT

Hi Guys,

here i am using prdsale data set. I am trying to color the quarter column on basis of their number. Ex 1=pink 2=yellow 3=green 4=red.

below is my code but it is not working.

proc report data=sashelp.prdsale;
column product quarter;
/*define quarter/ group;*/
COMPUTE quarter;
IF quarter >3
THEN CALL DEFINE(_col_, "style", "STYLE=[BACKGROUND=RED]");
ENDCOMP;
run;

Re: Call define in proc report

Ksharp — Sat, 05 May 2018 11:07:53 GMT

By default, numeric variable is ANALYSIS usage, therefore refer to it by xxx.sum .

proc report data=sashelp.prdsale nowd;
column product quarter ;
/*define quarter/ group;*/
COMPUTE quarter;
IF quarter.sum >3
THEN CALL DEFINE(_col_, "style", "STYLE=[BACKGROUND=RED]");
ENDCOMP;
run;

Re: Call define in proc report

Ajayvit — Sat, 05 May 2018 11:57:44 GMT

Thanks Ksharp

Re: Call define in proc report

Cynthia_sas — Sat, 05 May 2018 21:37:36 GMT

Hi:

You can also accomplish what you want to do with a format, no CALL DEFINE needed.

Cynthia

proc format;
  value qfmt 1='pink'
             2='yellow'
             3='green'
             4='red';
run;
  
proc report data=sashelp.prdsale;
column product quarter;
define quarter /
       style(column)={background=qfmt.};
run;

Re: Call define in proc report

Ajayvit — Sun, 06 May 2018 04:17:41 GMT

Thanks Cynthia