topic Re: Interactive rtf/pdf document with links in ODS and Base Reporting

Interactive rtf/pdf document with links

DmytroYermak — Thu, 29 Mar 2018 07:21:21 GMT

Hi all,

Could you please help with the table reporting that should contain links on the correspondent files. I have a dataset that with tables names and should receive a one column with the names and each name should be an interactive.

It has to be an rtf and pdf documents. Is it possible with SAS?

data test;
  format TABLE $6. LINK $25.;
  input TABLE LINK;
  datelines;
Table1 C:\ProjectX\Table1.rtf
Table2 C:\ProjectX\Table2.rtf
Table3 C:\ProjectX\Table3.rtf
;
run;

Thank you!

Re: Interactive rtf/pdf document with links

BrunoMueller — Thu, 29 Mar 2018 09:47:27 GMT

You can use Proc REPORT with the CALL DEFINE and the URL attribute to set your link. See sample code below.

Also have a look at http://support.sas.com/kb/24/182.html concerning the color around the link

data test;
  format TABLE $6. LINK $25.;
  input TABLE LINK;
  datalines;
Table1 C:\ProjectX\Table1.rtf
Table2 C:\ProjectX\Table2.rtf
Table3 C:\ProjectX\Table3.rtf
;
run;

ods pdf file="c:\temp\sample.pdf";
proc report data=test;
  column table link _dummy;
  define table / display;
  define link / display noprint;
  define _dummy / computed noprint;
  compute _dummy;
    call define ("table", "URL", link);
/*    call define("table", "style", "style={LINKCOLOR=white}");*/
  endcomp;
run;
ods pdf close;

Re: Interactive rtf/pdf document with links

DmytroYermak — Thu, 29 Mar 2018 10:07:28 GMT

Thank you, Bruno! It has worked.