topic Re: Proc tabulate,want to delete left column for keyword such as mean median in ODS and Base Reporting

Proc tabulate,want to delete left column for keyword such as mean median

XiaoGuaiShou — Mon, 26 Feb 2018 17:29:02 GMT

Hi Everyone,

In proc tabulate, I run keyword to my data (for example, mean median), but I want to delete the left column with nothing as following snip shot:

How to resolve this? Any help would be greatly appreciated.

Thanks ahead,

The code I have:

data score;
   infile datalines delimiter=','; 
   input name $ score  YEAR ;
   datalines;                      
John,98,2018
Mary,95,2017
Tom,100,2016
Jerry,80,2016
;

proc tabulate data=score;
		class YEAR/ order=data preloadfmt;
		classlev YEAR;
        var score;

	table score=""*(n='Number of Respondents'*f=comma10. min='Minimum'*f=dollar10. q1='Lower Quartile'*f=dollar10.
	mean='Average'*f=dollar10. median='Median'*f=dollar10. q3='Upper Quartile'*f=dollar10. max='Maximum'*f=dollar10. stddev='Standard Deviation'*f=dollar10.)*[style=[JUST=r vjust=c]]	,
(YEAR= "")*[style=[Cellwidth=200]]/box={s=[just=L]} style_precedence=row printmiss misstext='' ;
run;

Re: Proc tabulate,want to delete left column for keyword such as mean median

PGStats — Mon, 26 Feb 2018 20:18:07 GMT

Try

options missing="";
proc tabulate data=score;
	class YEAR/ order=data preloadfmt;
	classlev YEAR;
    var score;
	table (n='Number of Respondents'*f=comma10. min='Minimum'*f=dollar10. 
        q1='Lower Quartile'*f=dollar10.
    	mean='Average'*f=dollar10. median='Median'*f=dollar10. 
        q3='Upper Quartile'*f=dollar10. max='Maximum'*f=dollar10. 
        stddev='Standard Deviation'*f=dollar10.)*[style=[JUST=r vjust=c]] ,
        score=""*(YEAR= "")*[style=[Cellwidth=200]]/box={s=[just=L]} 
        style_precedence=row printmiss misstext='' ;
run;

Re: Proc tabulate,want to delete left column for keyword such as mean median

XiaoGuaiShou — Mon, 26 Feb 2018 20:58:04 GMT

WOW! I want to say it is awesome~! It is exactly what I want. Thank you so much.