Proc report grouping twice

Matt3 — Wed, 25 Oct 2017 07:26:21 GMT

Hi,

could anyone please tell me if is it possible to group over one variable and then use another group in same table.

I would like to obtain results like that:

GroupVar1 - first level grouping variable

Var2 - sum of var2 in datasets grouped by GroupVar1

GroupVar3 - second level grouping variable

Var4, Var5 - sum of variables grouped by GroupVar1 and GroupVar3

Thank you.

Re: Proc report grouping twice

BrunoMueller — Wed, 25 Oct 2017 08:01:08 GMT

This can be done with Proc REPORT, you do need to add a dummy content column for the first summarized var.

The code below shows an example, please note that there are some additional statements, that where added for verification of the result.


data cars;
  set sashelp.cars;
  hpg = 1;
run;
proc report data=cars spanrows;
  column origin hpg horsepower=hpsum type invoice cylinders _dummy;
  define origin / group style={textalign=center VERTICALALIGN=MIDDLE };
  define hpg / group style={textalign=center VERTICALALIGN=MIDDLE };
  define hpsum / analysis sum
/*    noprint*/
  ;
  define type / group;
  define cylinders / analysis;
  define invoice / analysis;
  define _dummy / computed
/*    noprint*/
  ;

  compute before origin;
     tempHpg = hpsum;
  endcomp;

  /* assign value to grouping var */
  compute _dummy;
    /* just for verification */
    _dummy = tempHpg;
    hpg = tempHpg;
  endcomp;

  /* just for validation */
  break after origin / summarize;
run;

topic Re: Proc report grouping twice in ODS and Base Reporting

Proc report grouping twice

Re: Proc report grouping twice