topic Re: PROC REPORT continued page in ODS and Base Reporting

PROC REPORT continued page

JohnChen_TW — Mon, 04 Sep 2017 03:14:10 GMT

Hi everyone,

I'm using SAS9.3.

I have no idea why the 'Note' at the end of table cannot be presented on every single page when the total page of tale is more than 1.

(In some tables, it is only presented on the last page. Why?)

Here is my partial code:

proc template...;
...
replace Table from Output / frame=above;
...
end;
run;

And I put "Note: xxx" using:

compute after _page_/style={just=l font_face='Arial' font_size=10pt bordertopcolor=black bordertopwidth=0.25};
line "Note:";
line "The unit of age is year";
endcomp;

Here is ODS destination I'm using: (I need both RTF and PDF)

PROC REPORT;
...
...
...
RUN;

ODS RTF file="xxxxx.rtf"  style=xxxxx ;  
ODS PRINTER PDF file="xxxxx.pdf"  style=xxxxx replay; run;
ODS PRINTER PDF PDF CLOSE;
ODS RTF CLOSE;

Re: PROC REPORT continued page

Reeza — Mon, 04 Sep 2017 03:17:52 GMT

What output destination are you using? The concept of what's a PAGE boundary varies, HTML doesn't have boundaries.

FOOTNOTES text do repeat at the end of each page for a table that crosses over page boundaries.

http://www2.sas.com/proceedings/forum2008/031-2008.pdf

There's a note (pg 14) in paper above about this not working as expected in RTF docs.

Re: PROC REPORT continued page

JohnChen_TW — Mon, 04 Sep 2017 03:58:24 GMT

HI @Reeza

I'm sorry, I do not know what OUTPUT destination is...

Like the graph above, I'd like to show 'Note: *The unit of age is year' on each page.

Yes, FOOTNOTES can repeat at the end of each page for a table, but I need to print the Note above following the bottom border line, not at the footer.

In some tables which were printed by the same code, "Note:xxxx" can be printed on each page.

But in other tables, it was printed on the only last few pages. Why?

Re: PROC REPORT continued page

Reeza — Mon, 04 Sep 2017 05:02:17 GMT

Because different outputs (PDF, RTF, HTML) have different definitions of what a 'page' is.

The paper goes into more detail and you can probably search at Lexjansen, but the workaround does appear to use a footnote.

Re: PROC REPORT continued page

JohnChen_TW — Mon, 04 Sep 2017 05:50:06 GMT

I'm using ODS RTF to output the report and using ODS PRINTER PDF to print the report in PDF.

I mean there are several tables (Table 1, 2, ...etc) included in one file (RFT or PDF), but "Note:xxx" cannot be shown on each page of all tables.
For example, I got the file named have.pdf (or rft) which is including 5 tables and each of table has three pages.

However, when I was using

option nodate nonumber papersize=A4 topmargin="0.75in";
ods escapechar='^';
ods document name=WORK.CONTENTS(write);
title1 j=left "NAME";
footnote1 j=left "PATH://";

PROC REPORT DATA=Table1;
...
...
...
compute after _page_/style={just=l font_face='Arial' font_size=10pt bordertopcolor=black bordertopwidth=0.25};
line "Note:";
line "The unit of age is year";
endcomp;
RUN;

ODS RTF file="Table1.rtf"  style=xxxxx ;  
ODS PRINTER PDF file="Table1.pdf"  style=xxxxx replay; run;
ODS PRINTER PDF PDF CLOSE;
ODS RTF CLOSE;
/*********************************************************************************/

option nodate nonumber papersize=A4 topmargin="0.75in";
ods escapechar='^';
ods document name=WORK.CONTENTS(write);
title1 j=left "NAME";
footnote1 j=left "PATH://";

PROC REPORT DATA=Table2;
...
...
...
compute after _page_/style={just=l font_face='Arial' font_size=10pt bordertopcolor=black bordertopwidth=0.25};
line "Note:";
line "The unit of age is year";
endcomp;
RUN;

ODS RTF file="Table2.rtf"  style=xxxxx ;  
ODS PRINTER PDF file="Table2.pdf"  style=xxxxx replay; run;
ODS PRINTER PDF PDF CLOSE;
ODS RTF CLOSE;
/*********************************************************************************/

option nodate nonumber papersize=A4 topmargin="0.75in";
ods escapechar='^';
ods document name=WORK.CONTENTS(write);
title1 j=left "NAME";
footnote1 j=left "PATH://";

PROC REPORT DATA=Table3;
...
...
...
compute after _page_/style={just=l font_face='Arial' font_size=10pt bordertopcolor=black bordertopwidth=0.25};
line "Note:";
line "The unit of age is year";
endcomp;
RUN;

ODS RTF file="Table3.rtf"  style=xxxxx ;  
ODS PRINTER PDF file="Table3.pdf"  style=xxxxx replay; run;
ODS PRINTER PDF PDF CLOSE;
ODS RTF CLOSE;
/*********************************************************************************/

option nodate nonumber papersize=A4 topmargin="0.75in";
ods escapechar='^';
ods document name=WORK.CONTENTS(write);
title1 j=left "NAME";
footnote1 j=left "PATH://";

PROC REPORT DATA=Table4;
...
...
...
compute after _page_/style={just=l font_face='Arial' font_size=10pt bordertopcolor=black bordertopwidth=0.25};
line "Note:";
line "The unit of age is year";
endcomp;
RUN;

ODS RTF file="Table4.rtf"  style=xxxxx ;  
ODS PRINTER PDF file="Table4.pdf"  style=xxxxx replay; run;
ODS PRINTER PDF PDF CLOSE;
ODS RTF CLOSE;
/*********************************************************************************/

option nodate nonumber papersize=A4 topmargin="0.75in";
ods escapechar='^';
ods document name=WORK.CONTENTS(write);
title1 j=left "NAME";
footnote1 j=left "PATH://";

PROC REPORT DATA=Table5;
...
...
...
compute after _page_/style={just=l font_face='Arial' font_size=10pt bordertopcolor=black bordertopwidth=0.25};
line "Note:";
line "The unit of age is year";
endcomp;
RUN;

ODS RTF file="Table5.rtf"  style=xxxxx ;  
ODS PRINTER PDF file="Table5.pdf"  style=xxxxx replay; run;
ODS PRINTER PDF PDF CLOSE;
ODS RTF CLOSE;

assume that the "Note:xxx" can be shown on each page in Table1, 3, 4, but only can be shown on the last page in Table 2 and 5.

I'd like to know why did it happen, and how to resolve this problem.

Re: PROC REPORT continued page

Reeza — Mon, 04 Sep 2017 05:54:39 GMT

I think this is beyond me, especially at this time.

I would suggest posting the log and your exact SAS version as well, ie SAS 9.3TS2M1

Re: PROC REPORT continued page

JohnChen_TW — Mon, 04 Sep 2017 06:32:37 GMT

I found the common point in these tables where the "Note:xxx" cannot be shown on each page is that the footnote would be printed in BOLD on the first page of the table (e.g.: Page 1 of xx), but printed normality on the following pages.
Maybe it's the key to the problem?

BTW, I do not know how to find the exact version of SAS...

JC

Re: PROC REPORT continued page

Cynthia_sas — Mon, 04 Sep 2017 16:05:36 GMT

Hi:

To find the exact version of SAS that you're running, submit this code:

%put -----> version is &sysvlong4;

Which on my system, results in this:

That shows you the exact version of SAS you are using...in the above case, 9.4 maintenance release M3.

cynthia

Re: PROC REPORT continued page

JohnChen_TW — Tue, 05 Sep 2017 01:10:36 GMT

Hi @Cynthia_sas and @Reeza,

My SAS version is,

Re: PROC REPORT continued page

JohnChen_TW — Tue, 05 Sep 2017 12:20:34 GMT

Hi @Cynthia_sas,
My SAS version is 9.03.01M2P08152012.
Do you have any suggestion?

I still have no idea how to show the NOTE on each page in one table by ODS RTF. (above)

JC

Re: PROC REPORT continued page

Reeza — Sat, 09 Sep 2017 03:09:49 GMT

If you still need assistance with this I suggest Tech Support. We don't have enough information to test it - ie no code with data to replicate the issue. Plus the version of SAS you're using is fairly old, so Tech Support may have access to it but most of the other users will not.

Re: PROC REPORT continued page

Cynthia_sas — Sat, 09 Sep 2017 16:33:46 GMT

Hi:

It is impossible to run your code because you haven't provided everything. I no longer have 9.3 to test with, but this is the output I get with some fake data created from SASHELP.CLASS so my final output will have 4 pages -- with 1 "name" on every page. Here's the output -- as you see, I get the NOTE from the COMPUTE block on every page (I changed your code slightly to make the note red, so it would be clearly visible on every page, even at a reduced size):

Here's the code I used:

** make some fake data;
** use BIGGROUP for paging;
** will have 1 page of 25 obs for each name;
data bigclass;
  set sashelp.class(obs=4);
  biggroup = _n_;
  do i = 1 to 25;
    output;
  end;
run;
 
** sort;
proc sort data=bigclass;
  by biggroup name;
run;
   
** use PROC REPORT and ODS RTF to get 1 page for every BIGGROUP value;
** will have 4 pages. Should see note on every page, underneath table;
    
** use ODS DOCUMENT to capture PROC REPORT output;
         
ods document name=work.testdoc;
ods rtf file='c:\temp\bigclass1.rtf';
proc  report data=bigclass;
  column biggroup name age height weight sex;
  define biggroup / order page;
  define name / display;
  break after biggroup / page;
  compute after _page_/
          style={just=l font_face='Arial' font_size=10pt color=red fontweight=bold};
      line "Note:";
      line "The unit of age is year";
  endcomp;
RUN;
ods rtf close;
  
ods document close;
  
** now replay the saved document output; 
ods rtf file='c:\temp\replaydoc.rtf';
ods pdf file='c:\temp\replaydoc.pdf';
   
proc document name=work.testdoc;
replay;
run;
quit;
  
ods _all_ close;

Since you didn't show your ODS DOCUMENT and since you didn't really explain why you had ODS RTF and ODS PRINTER PDF statements, I only experimented with ODS RTF in my test code. However, I do get the NOTE output at the bottom of each page.

But I used ODS DOCUMENT to save the PROC REPORT output to a document store and then did a replay to RTF and PDF and again, the NOTE from the COMPUTE block appeared on every page.

So I think that Reeza's suggestion is probably a good one -- to work with Tech Support. They can look at ALL of your code and ALL of your data and they have 9.3 available for testing -- so they can help you best.

However, you could try to run my test code and if your results are the same as my results, then my suggestion would be for you to revisit your code using my test code as the model and see whether you can debug your way to a solution.

cynthia

Re: PROC REPORT continued page

MINX — Mon, 11 Sep 2017 14:58:25 GMT

Hi @JohnChen_TW

I think you did not page break your table. Although table is displayed in multiples pages, SAS consider this is still one page if you did not use 'break after pagebreak_variable/page' or BY statement in PROC REPORT. That is why you only see the note is only displayed at the last page.

Re: PROC REPORT continued page

JohnChen_TW — Tue, 12 Sep 2017 01:38:07 GMT

HI @MINX,

Thanks for your input.

This is a weird issue because the note is not always displayed only at the last page, in some tables, the note could be displayed at the bottom of each page based on the same code.

Re: PROC REPORT continued page

JohnChen_TW — Tue, 12 Sep 2017 03:01:45 GMT

Hi @Cynthia_sas,

Sorry, I do not know much about "PROC REPORT"...

Here are a fake data and output.

data have; length sno group name sex res ans $200;
infile cards dlm=',';
input sno group name sex res ans;
cards;
2	,	Gorup 1	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 1	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 1	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 1	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 1	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 1	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 1	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 1	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 1	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 1	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 1	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 1	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 1	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 1	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 1	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 2	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 3	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 3	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 3	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 4	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 4	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 4	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 5	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 5	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 5	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 5	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 5	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 5	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 5	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 5	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 5	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 5	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 5	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 5	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 6	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 6	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 6	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 6	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 6	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,   xxx
2	,	Gorup 6	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 6	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 6	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 7	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Group 8	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Group 9	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 10	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 10	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 10	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 10	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 10	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
2	,	Gorup 10	,	xxxxxxxxxxxxx	,	Female	,	xxxxx	,	xxx
;
run;

options nodate nonumber papersize=A4 topmargin="0.75in" missing=' '; 
ods escapechar='^';
ods document name=work.testdoc(write);
ods rtf file="&outpath\test.rtf";
PROC REPORT DATA=have NOWD
	center                
	headskip
	split='|' 
	ls=256;
	title1 j=r "Page ^{thispage} of ^{lastpage}";
	title5 j=c "Example";
	title6	j=c "Proc Report";
	footnote1 j=l "footnote";
    columns sno group name sex res ans;
	define sno	 					/center	style=[cellwidth=20mm]   	'Subject ID';
	define group 		 			/center	style=[cellwidth=45mm]   	'Test Group';
	define name					/left		style=[cellwidth=60mm]   	'Test Name';
	define sex  					/center	style=[cellwidth=15mm]   	'Gender';
	define res 						/center	style=[cellwidth=40mm]   	'Result';
	define ans  					/center	style=[cellwidth=25mm]   	'Yes/ No';
	compute after _page_/style={just=l font_face='Arial' font_size=9pt borderbottomcolor=white};
		line "Note:";
		line "Why the note cannot be displayed on each page...?";
	endcomp;
RUN;
ods rtf close;
ods document close;
ods rtf file="&outpath\test.rtf" sectiondata='\headery540\footery540' style=Styles.mystyle;
ods pdf file="&outpath\test.pdf" style=Styles.mystyle;
proc document name=work.testdoc;
replay;
run;
quit;

ods _all_ close;

The note is displayed only on the last two pages.

Re: PROC REPORT continued page

MINX — Tue, 12 Sep 2017 13:57:01 GMT

@JohnChen_TW, There are a lot of ways to page break tables. Below is one simple example to page break for 16 observations per page.

data have;
	set have;
	p = ceil (_n_/16);
run;

options nodate nonumber papersize=A4 topmargin="0.75in" missing=' ' orientation=landscape; 
ods escapechar='^';
ods document name=work.testdoc(write);
ods rtf file="&outpath\test.rtf";
PROC REPORT DATA=have NOWD
	center                
	headskip
	split='|' 
	ls=256;
	title1 j=r "Page ^{thispage} of ^{lastpage}";
	title5 j=c "Example";
	title6	j=c "Proc Report";
	footnote1 j=l "footnote";
    columns p sno group name sex res ans;
	define p 						/order noprint;
	define sno	 					/center	style=[cellwidth=20mm]   	'Subject ID';
	define group 		 			/center	style=[cellwidth=45mm]   	'Test Group';
	define name						/left		style=[cellwidth=60mm]   	'Test Name';
	define sex  					/center	style=[cellwidth=15mm]   	'Gender';
	define res 						/center	style=[cellwidth=40mm]   	'Result';
	define ans  					/center	style=[cellwidth=25mm]   	'Yes/ No';
	break after p/page;
	compute after _page_/style={just=l font_face='Arial' font_size=9pt borderbottomcolor=white};
		line "Note:";
		line "Why the note cannot be displayed on each page...?";
	endcomp;
RUN;
ods rtf close;
ods document close;
ods rtf file="&outpath\test.rtf" sectiondata='\headery540\footery540' ;
ods pdf file="&outpath\test.pdf" ;
proc document name=work.testdoc;
replay;
run;
quit;

ods _all_ close;

Re: PROC REPORT continued page

Cynthia_sas — Wed, 13 Sep 2017 03:59:28 GMT

John,
The issue with your original code is that you are not telling PROC REPORT anything that will cause the COMPUTE AFTER _PAGE_ to execute.

You are correct that when the RTF or PDF output is RENDERED, the file appears on multiple pages in paged destinations. However, without using a BY statement (to cause a logical page break) or a "helper" variable, as shown in my code or the code from Minx, then there is nothing for PROC REPORT to do except generate the output as though it is one logical page, therefore only at the bottom will you see the note. However, with BY group processing, the BY group is a logical group and the BY statement causes a LOGICAL page break between every BY group. This happens within PROC REPORT -- before the output is rendered -- so SAS and PROC REPORT write the NOTE at the end of every BY group, every logical page.

If you need to have something appear on the physical pages, at the end of every physical page, either use a FOOTNOTE statement or use a COMPUTE AFTER _PAGE_ where you control the page break within PROC REPORT.

You've now gotten 2 examples of how to do this and with my example, I provided a picture of the note appearing on every page when the output was rendered in Word.

There should be something in all the code that's been posted to help you figure it out.

cynthia

Re: PROC REPORT continued page

JohnChen_TW — Wed, 13 Sep 2017 05:59:08 GMT

Thank you, @Cynthia_sas for your reply.

Ok, as you said, the note would not be displayed on every page without using BY statement or other logical statements.

But as my previous example (in PDF), I'm wondering why the note can be displayed on the last two pages, not only at the bottom of the table?

I've tried to break page by counting the number of lines in one page, and then made a flag variable to identify when to break at one page as the way Minx provided. However, this is not a general resolution for me since sometimes the data would be cut off to next row due to the width of the layout. Also, the number of lines in one page I counted is the "number of observations in SAS data set" instead of the practical lines displayed on the output.

Also, I've tried another way to break page as well using BREAK AFTER "Specific variable" / PAGE. However, assuming the specific variable is "sno (Subject ID)" and the number of observations among subjects is quite different, then the output will look like a discontinuous table.

Sorry, FOOTNOTE was populated other information, so I'd like to put the note at the bottom of table on each page.

Or is there a suggestion how to keep the space between the bottom of table on one page and the footnote in order to populate the note?

Re: PROC REPORT continued page

Cynthia_sas — Wed, 13 Sep 2017 13:17:26 GMT

Hi:

When I ran your original code, I noticed the wrapping -- that will interfere with page breaking, so in my program, I adjusted the widths so that all the columns fit in the page width. I generally do not try to overcontrol the column width by specifying a width for every column, but if you do, you have to also make sure that the widths you specify do not exceed the width remaining after you subtract the left and right margin width.

I found other oddities in your code, such as a LS specification in PROC REPORT, which is ignored for RTF, PDF and ODS DOCUMENT, so that was unnecessary. Here's the modified code I tried:

data have; 
length sno group name sex res ans $200;
infile cards dlm=',';
input sno group name sex res ans;
cards;
2,Group 1,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 1,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 1,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 1,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 1,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 1,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 1,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 1,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 1,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 1,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 1,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 1,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 1,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 1,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 1,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 2,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 3,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 3,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 3,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 4,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 4,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 4,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 5,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 5,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 5,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 5,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 5,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 5,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 5,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 5,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 5,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 5,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 5,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 5,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 6,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 6,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 6,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 6,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 6,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 6,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 6,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 6,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 7,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 8,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 9,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 10,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 10,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 10,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 10,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 10,xxxxxxxxxxxxx,Female,xxxxx,xxx
2,Group 10,xxxxxxxxxxxxx,Female,xxxxx,xxx
;
run;

 
ods html close;
** use original data -- with adjusted widths;
** so that all columns fit in the papersize;
** in this instance, LS=256 is not relevant for RTF;
** because only the papersize and margins impact RTF and PDF;
** the note will ONLY appear on the last page because that is the end of the logical page;
** even though the table will need multiple physical pages to display in RTF.;
** _PAGE_ only comes into play when PROC REPORT issues an internal "page break" and;
** NOT when RTF renders a physical page break in Word;
options nodate nonumber papersize=A4 topmargin="0.75in" 
        leftmargin=2.5mm rightmargin=2.5mm bottommargin=0.75in missing=' '; 
ods escapechar='^';
ods rtf file="c:\temp\test.rtf";
PROC REPORT DATA=have NOWD
    center                
    split='|' ;
    title1 j=r "Page ^{thispage} of ^{lastpage}";
    title3 j=c "1 Example";
    title5  j=c "Proc Report without paging variable";
    footnote1 j=l "This appears on every page";
    columns sno group name sex res ans;
    define sno   /display center style(column)=[cellwidth=20mm] 'Subject ID';
    define group /display center style(column)=[cellwidth=25mm] 'Test Group';
    define name /display left   style(column)=[cellwidth=80mm] 'Test Name';
    define sex  /display center style(column)=[cellwidth=15mm] 'Gender';
    define res  /display center style(column)=[cellwidth=30mm] 'Result';
    define ans  /display center style(column)=[cellwidth=15mm] 'Yes/No';
    compute after _page_/style={just=l font_face='Arial' font_size=9pt};
        line "Note:";
        line "Why the note cannot be displayed on each page...?";
    endcomp;
RUN;
ods rtf close;

This document is one logical page. And if you look, PROC REPORT writes the note only at the end, as designed:

I did change the code to show a footnote at the bottom of each page, which is traditionally, how you put something on each page in RTF because SAS writes the footnote text using the RTF controls for footers, just as the title text is written using the RTF controls for headers.

There was an alternate TAGSET for RTF written -- TAGSETS.RTF_SAMPLE -- I generally don't use it because the developer said (here https://communities.sas.com/t5/ODS-and-Base-Reporting/RTF-Tagset-and-PROC-REPORT-SPANROWS/td-p/12905 ) that it was never tested enough to be production. It was improved in SAS 9.3 and this tagset does give you the results you want with your COMPUTE AFTER, as shown below -- but I found it better to remove your width specifications to get this:

here's the changed code I used for tagsets.rtf_sample destination:

options nodate nonumber papersize=A4 topmargin="0.75in" 
        leftmargin=2.5mm rightmargin=2.5mm bottommargin=0.75in missing=' '; 
ods escapechar='^';
ods tagsets.rtf_sample file="c:\temp\tr_sample.rtf";
PROC REPORT DATA=have NOWD
    style(report)={width=100%}
    center                
    split='|' ;
    title1 j=r "Page ^{thispage} of ^{lastpage}";
    title3 j=c "1 alt Example";
    title5  j=c "Proc Report without paging variable";
    footnote1 j=l "This appears on every page";
    columns sno group name sex res ans;
    define sno   /display center 'Subject ID';
    define group /display center  'Test Group';
    define name /display left  'Test Name';
    define sex  /display center 'Gender';
    define res  /display center  'Result';
    define ans  /display center  'Yes/No';
    compute after _page_/style={just=l font_face='Arial' font_size=9pt};
        line "Note:";
        line "Why the note cannot be displayed on each page...?";
    endcomp;
RUN;
ods tagsets.rtf_sample close;

However, this was just an example with TAGSETS.RTFSAMPLE outside the realm of using ODS DOCUMENT. So I don't know whether that is going to work for you in the long run.

Typically what people do when they need to control what appears from a COMPUTE AFTER _PAGE_ block is to take control of page breaks. This is how I did it with your data and modified widths -- so the columns on the report fit within the margins:

** create a "fake" or "helper" page variable called page_break;
** so that every 30 obs will be assigned the same value for page_break;
data newhave;
  set have;
  page_break = ceil(divide(_n_,30));
run;
  
** now use that page_break variable to control what gets written at the end of every;
** logical page because the page_break variable has break processing turned on with;
** the BREAK statement;
options nodate nonumber papersize=A4 topmargin="0.75in" 
        leftmargin=2.5mm rightmargin=2.5mm bottommargin=0.75in missing=' '; 
ods escapechar='^';
ods rtf file="c:\temp\alt_page_test.rtf";
PROC REPORT DATA=newhave NOWD
    center                
    split='|' ;
    title1 j=r "Page ^{thispage} of ^{lastpage}";
    title3 j=c "2 Example";
    title5  j=c "Proc Report with paging variable";
    footnote1 j=l "This appears on every page";
    columns page_break sno group name sex res ans;
    define page_break / order page noprint;
    define sno   /display center style(column)=[cellwidth=20mm] 'Subject ID';
    define group /display center style(column)=[cellwidth=25mm] 'Test Group';
    define name /display left   style(column)=[cellwidth=80mm] 'Test Name';
    define sex  /display center style(column)=[cellwidth=15mm] 'Gender';
    define res  /display center style(column)=[cellwidth=30mm] 'Result';
    define ans  /display center style(column)=[cellwidth=15mm] 'Yes/No';
    break after page_break / page;
    compute after _page_/style={just=l font_face='Arial' font_size=9pt};
        line "Note:";
        line "Now the note can be displayed on each page...because of BREAK after page_break statement";
    endcomp;
RUN;
ods rtf close;

with these results:

As you can see, I had to make a special "helper" variable called page_break and then my BREAK statement became BREAK AFTER page_break / page; which allowed the COMPUTE AFTER _PAGE_ to write the line for every logical page, as set by the page_break variable. Typically, unless you are doing BY group processing, you would not use a variable like your SNO for page breaking unless it really was being used for BY group processing. That's why my example and the other example both created a "helper" variable.

cynthia

Re: PROC REPORT continued page

JohnChen_TW — Thu, 21 Sep 2017 04:03:58 GMT

Hi, @Cynthia_sas

Many thanks for your suggestion.

However, if there are too many columns in one table, the data will be cut off to the next page when without width specifications.

Maybe there is no appropriate code to resolve this non-logical data...

It is an uncertainty that how long of column length will data employed before generating the table.

Thanks again!