topic How to highlight a column in ODS and Base Reporting

How to highlight a column

tekish — Tue, 30 Aug 2016 13:42:55 GMT

I want to highlight Weight column in excel output.

when Weight is less than Height .

/*SAS code*/

ods tagsets.excelxp file="bylines.xls" style=statistical

options( suppress_bylines='yes' sheet_interval='none' );

proc report data=class nowd;

column name age sex height weight ;

define name / display;

define age / display;

define sex / order;

define height / sum;

define weight / sum;

compute age;

if age < 13 then call define(_col_,"style","style={background=red}");

endcomp;

compute weight;

if weight < height then call define(_col_,"style","style={background=blue}");

endcomp;

run;

ods _all_ close;

Thanks.

Re: How to highlight a column

Cynthia_sas — Tue, 30 Aug 2016 14:16:29 GMT

Hi:
I would expect that you are getting highlighting for AGE, but not for the WEIGHT column. When you use an analysis variable in a COMPUTE block, you do not refer to the simple name. You must use the convention varname.statistic.

So in this case, you show that statistic of SUM for HEIGHT and WEIGHT, then you need to refer to them in your COMPUTE block as:
HEIGHT.SUM and WEIGHT.SUM

or

if weight.sum < height.sum then call define(...);

cynthia

Re: How to highlight a column

Ksharp — Tue, 30 Aug 2016 14:24:19 GMT

Since weight and height has ANALYSIS usage, you should use .sum to refer to them.


compute weight;
if weight.sum < height.sum then call define(_col_,"style","style={background=blue}");
endcomp;

Re: How to highlight a column

tekish — Tue, 30 Aug 2016 14:38:51 GMT

It works.

Thanks

kesete

Re: How to highlight a column

tekish — Tue, 30 Aug 2016 14:39:23 GMT

It works,

Thanks,