topic Re: ODS HTML Report Outlook in ODS and Base Reporting

ODS HTML Report Outlook

jdmarshg — Mon, 18 Jan 2016 03:11:01 GMT

Hello everyone.

I'm looking to get a report from a dataset to have alternating row colors.
Which would be the best to go with ?

HTML

msoffice2k

odsTagsetsTableEditor

Filename output email to="jonathan@.com"
content_type="text/html"
subject="DataSet Report" Attach="/data/ETL_work/DATA_DEV/Reports/&dataset..xls";;
ods html3 file=output style=HTMLblue;
*ods msoffice2k file=output style=HTMLblue*/
/*metatext='name="viewport" content="width="device-width"'*/
/*options(pagebreak="no" );*/
*ods tagsets.Tableeditor file=output options(format_email='yes'
pagebreak="no")
style=HTMLblue;
title1 "&dataset Report";
proc odstext;
list;
item "Profile Summary for &dataset";
item "For Date of &sysdate";
item "For All &DqzDateVerTime";
end;
run;
/*proc print data=sashelp.orsales;*/
/*var Year Product_Line Product_Group Quantity Profit;*/
/*run;*/

proc print data=DataReport;
run;
/*ODS tagsets.excelxp close;*/

ods _all_ close;

I tried using this with each of the tagsets.

Continuing to research but wondering if I'm headed in the right direction.

Re: ODS HTML Report Outlook

Tim_SAS — Thu, 29 Oct 2015 19:01:57 GMT

I think you're asking the wrong question. Alternating row colors isn't a function of the destination. You can get alternating row colors with any stylable destination. Here's how to create an HTML report with alternating row colors. If you want the report in ExcelXP format, simply substitute tagsets.excelxp for html in the ODS statement.

/*
 *  Assign alternating colors to the rows of a report
 */
ods html file="altcolor.html";
ods listing close;

proc report nowd data=sashelp.class
        style(header)=[background=#f0f0f0 foreground=black vjust=bottom];
    col name sex age height weight;
    define name--weight / display;
compute name;
    bg + 1;
    if mod(bg, 2) = 1 then
        call define(_row_, "style", "style={background=white}");
    else
        call define(_row_, "style", "style={background=#d1e9d1}");
endcomp;
run;

ods listing;
ods html close;

Re: ODS HTML Report Outlook

jdmarshg — Thu, 29 Oct 2015 21:12:41 GMT

I just resolved.

Thank you Tim this worked great much appreciated.