topic Re: Print Line of Text to Tagsets.ExcelXp in ODS and Base Reporting

Print Line of Text to Tagsets.ExcelXp

wcp_fnfg — Mon, 28 Jul 2014 20:46:51 GMT

I can use data _null_ and file print, but not matter what, when it shows up in excel, it has a period in front of the text. Any alternatives\fixes?

data _null_;

file print;

put 'Hi Wes';

run;

Ends up as

.Hi Wes

(The period is not present in the output window, just excel.

EG5.1

Re: Print Line of Text to Tagsets.ExcelXp

Chevell_sas — Mon, 28 Jul 2014 21:05:36 GMT

To prevent this behavior, you can use the tagset option Ascii_dots="no". The default of this option is yes.

Re: Print Line of Text to Tagsets.ExcelXp

wcp_fnfg — Thu, 31 Jul 2014 12:55:23 GMT

Yup that works.

Any idea how to style that text, like bold, italics, weight, etc?

Re: Print Line of Text to Tagsets.ExcelXp

Cynthia_sas — Thu, 31 Jul 2014 13:25:03 GMT

Hi:

You can use ODS ESCAPECHAR functions with STYLE overrides to alter the text. You could look at changing the style template. I don't remember off the top of my head which style element you would change. The Data element, I think. Or you could use a PROC REPORT approach. See the code below.

Cynthia

ods tagsets.excelxp file='c:\temp\data_null_xp1.xml'
    style=htmlblue options(ascii_dots='no');
ods escapechar='^';
**Method 1;
data _null_;
file print;
put '^{style[font_weight=bold font_size=12pt color=purple]Hello World}';
put 'Twas Brillig and the slithy toves';
run;

ods tagsets.excelxp close;

data world;
length text $50;
text = 'Hello World';
output;
text='Twas Brillig and the slithy toves';
output;
run;

ods tagsets.excelxp file='c:\temp\proc_report2.xml'
    style=htmlblue ;

**Method 2;
proc report data=world nowd noheader
style(column)={font_weight=bold font_size=12pt color=purple};
column text;
run;

ods tagsets.excelxp close;