topic Re: Data Manipulation in New SAS User

Data Manipulation

Phamhhm — Wed, 08 May 2019 18:42:02 GMT

Hi,

Some values of my var X are 0, and i want to replace all of them by the previous value.

X Xnew

1 1

2 2

0 2

4 4

3 3

0 3

7 7

My code does not work:

DATA Tnew;

SET Told;

IF X=0 THEN Xnew=lag(X);

RUN;

thank for your help

Re: Data Manipulation

novinosrin — Wed, 08 May 2019 18:46:16 GMT

data have;
input X ;   
cards;
1     1
2     2
0     2
4     4
3     3
0     3
7     7
;

data want;
set have;
x=ifn(x=0,lag(x),x);
run;

Re: Data Manipulation

novinosrin — Wed, 08 May 2019 18:58:26 GMT

data have;
input X ;   
cards;
1     1
2     2
0     2
4     4
3     3
0     3
7     7
;

data want;
set have;
xnew=ifn(x=0,lag(x),x);
run;

Re: Data Manipulation

Phamhhm — Wed, 08 May 2019 19:00:36 GMT

Thank for your answer, the code works, but i forgot something

X Xnew

1 1

2 2

0 2

4 4

3 3

0 3

4 4

5 5

0 5

some rows have 2 or 3 consecutive zeros

Re: Data Manipulation

novinosrin — Wed, 08 May 2019 19:06:11 GMT

Ok @Phamhhm

Try


data have;
input X ;   
cards;
1     1
2     2
0     2
4     4
3     3
0     3
0     3
4     4
5     5
0     5
0     5
0     5
;

data want;
set have;
retain temp;
temp=ifn( x=0 and lag(x) ne 0 ,lag(x),temp);
xnew=ifn( x=0,temp,x);
drop temp;
run;

Re: Data Manipulation

novinosrin — Wed, 08 May 2019 19:09:26 GMT

Hi @Phamhhm

Forget the lag function, Just retain will do


data have;
input X ;   
cards;
1     1
2     2
0     2
4     4
3     3
0     3
0     3
4     4
5     5
0     5
0     5
0     5
;
data want;
set have;
retain t;
if x ne 0 then do;
t=x;
xnew=x;
end;
else xnew=t;
drop t;
run;

Re: Data Manipulation

Phamhhm — Wed, 08 May 2019 19:13:34 GMT

Thank you, problem solved