topic Re: Add Record in New SAS User

Add Record

SASPhile — Thu, 25 Apr 2019 17:09:51 GMT

Source
A
B
C

We expect to see A B C as sources. But sometimes the source may not have all three values.
I would like to add missing source in this case C with sum 0 to final table.

Source TA sum
A diabetes 100
B diabetes 200
C diabetes 0

Re: Add Record

ballardw — Thu, 25 Apr 2019 17:54:53 GMT

How are you generating the table? Code at least.

You might be able to use one of the procedures that supports PRELOADFMT to include all levels of a format for a variable in a table. That would require 1) a custom format for the variable with all of the levels and 2) the appropriate syntax for using PRELOADFMT.

Each procedure that allows use of the PRELOADFMT option has slight differences in syntax requirements so the following is only one way.

proc format library=work;
value $source
'A' = 'A'
'B' = 'B'
'C' = 'C'
;
run;

data example;
   input source $ value;
datalines;
A 123
A 5
B 43
B 18
A 8
;
run;

proc tabulate data=example;
   class source /preloadfmt  ;
   format source $source.;
   var value;
   table source,
         value*sum
         / printmiss misstext='0'
  ;
run;

Re: Add Record

PeterClemmensen — Thu, 25 Apr 2019 17:20:54 GMT

I don't understand this. Are A, B and C data sets or variables or?

Please be more specific

Re: Add Record

Astounding — Thu, 25 Apr 2019 17:34:23 GMT

Make your own shell with all the values:

data shell;
   sum=0;
   do source='A', 'B', 'C';
      output;
   end;
run;

Then you can merge it with your original data:

data want;
   merge shell have;
   by source;
run;

Re: Add Record

Ksharp — Fri, 26 Apr 2019 14:02:37 GMT

data level;
input source $;
cards;
A
B
C
;
run;

data example;
   input source $ value;
datalines;
A 123
A 5
B 43
B 18
A 8
;
run;
proc summary data=example classdata=level nway;
class source;
var value;
output out=want sum=;
run;