topic Re: Extract specific pattern in New SAS User

Extract specific pattern

SASPhile — Fri, 19 Apr 2019 19:04:22 GMT

X20l,p5,op3
cX3z,p4,op2(1)

Need help on extracting values that are after letter X and before first coma.

for :X20l,p5,op3----20l
for:cX3z,p4,op2(1)--3z

Re: Extract specific pattern

andreas_lds — Fri, 19 Apr 2019 19:15:47 GMT

Such problems are best solved by using a regular expression. I can't post working code right now, you need the functions prxmatch and prxposn. The regular expression should be "X(.+),“

Re: Extract specific pattern

Shemp — Fri, 19 Apr 2019 20:39:45 GMT

Try this:

data temp;
   length extracted_value $ 10;
   input char_str $ 1-20;
   extracted_value = prxchange('s/^[^X]*X(.*?)\x2C.*$/$1/',1,char_str);
   datalines;
X20l,p5,op3
cX3z,p4,op2(1)
;

Re: Extract specific pattern

PGStats — Sat, 20 Apr 2019 04:55:38 GMT

As suggested, a regular expression will do the job:

data temp;
if _n_ = 1 then prxId + prxParse("/X(\w+?),/i");
length extracted_value $ 10;
input char_str $ 1-20;
if prxMatch(prxId, char_str) then
    extracted_value = prxPosn(prxId, 1, char_str);
drop prxId;
datalines;
X20l,p5,op3
cX3z,p4,op2(1)
;

proc print data=temp noobs; run;

Remove the "i" in the pattern if the letter X at the beginning cannot be lowercase.

Re: Extract specific pattern

Ksharp — Sat, 20 Apr 2019 11:10:06 GMT

If it appeared only once, that would be easy.

data have;
input x $40.;
cards;
X20l,p5,op3
cX3z,p4,op2(1)
;
run;
data want;
 set have;
 pid=prxparse('/(?<=x).+?(?=,)/i');
 call prxsubstr(pid,x,p,l);
 want=substr(x,p,l);
run;

Re: Extract specific pattern

Ksharp — Sat, 20 Apr 2019 11:11:12 GMT


data want;
 set have;
 pid=prxparse('/(?<=x)[^,]+(?=,)/i');
 call prxsubstr(pid,x,p,l);
 want=substr(x,p,l);
run;