topic Re: PROC SGPLOT-removing the red from the default random list of colors in New SAS User

PROC SGPLOT-removing the red from the default random list of colors

JW_Hyde — Mon, 15 Apr 2019 18:44:38 GMT

I dont want to use the color red from this random list of colors in the plot. How do I omit the red color from the plot?

Re: PROC SGPLOT-removing the red from the default random list of colors

PeterClemmensen — Mon, 15 Apr 2019 18:46:36 GMT

Please show us your code if you want a usable code answer 🙂

Re: PROC SGPLOT-removing the red from the default random list of colors

JW_Hyde — Mon, 15 Apr 2019 18:52:19 GMT

ods html close;
ods listing close;
ods graphics / imagemap=on imagename="&imgcht1"
height=750px width=1200px
tipmax=1600 antialiasmax=1600;

ods html path=grf1 body="&tagcht1" ;

proc sgplot data=acctout;
yaxis
labelattrs=(size=8 color=black)
LABEL= '# of Requests'
refticks
min=0
valueattrs=(size=8 color=black )
;
xaxis
fitpolicy= rotatethin
labelattrs=(size=8 color=black)
;
title1 h=1.5 c=black j=c f=swissb
'PROD';
title2 h=1.0 c=gray j=c f=swissb
"Reported Day = &EDTT";
title3 h=1.0 c=gray j=c f=swissb
"By appname";

vbar date/response=req
group=appname dataskin=gloss;

run ;

Re: PROC SGPLOT-removing the red from the default random list of colors

PaigeMiller — Mon, 15 Apr 2019 19:17:39 GMT

In general, I am a believer in controlling the colors yourself, rather than let SAS do it for you. Thus, you could use the STYLEATTRS command in PROC SGPLOT, specifying the DATACOLORS= option and then you get whatever colors you want.

Re: PROC SGPLOT-removing the red from the default random list of colors

JW_Hyde — Mon, 15 Apr 2019 19:38:18 GMT

I would do that but I have a couple dozen categories and maybe more on the way.
That's a bit of a maintenance headache.

Re: PROC SGPLOT-removing the red from the default random list of colors

PeterClemmensen — Mon, 15 Apr 2019 20:23:26 GMT

I stole some code from the blog post What colors does PROC SGPLOT use for markers? that might help you.

This lets you control the colors in the Styleattrs Statement dynamically. Here, I drag the red color out of the picture

libname temp "C:/temp";
proc template;
source styles.statistical / file='temp.tmp'; /* write template to text file */
quit;
 
data Colors;
keep Num Name Color R G B;
length Name Color $8;
infile 'temp.tmp';                    /* read from text file */
input;
/* example string:  'gcdata1' = cx445694 */
k = find(_infile_,'gcdata','i');      /* if k=0 then string not found */
if k > 0 then do;                     /* Found line that contains 'gcdata' */
   s = substr(_infile_, k);           /* substring from 'gcdata' to end of line */
   j = index(s, "'");                 /* index of closing quote  */
   Name = substr(s, 1, j-1);          /* keyword                 */
   if j = 7 then Num = 0;             /* string is 'gcdata'      */
   else                               /* extract number 1, 2, ... for strings */
      Num = inputn(substr(s, 7, j-7), "best2.");  /* gcdata1, gcdata2,...     */
   j = index(s, "=");                 /* index of equal sign     */
   Color = compress(substr(s, j+1));  /* color value for keyword */
   R = inputn(substr(Color, 3, 2), "HEX2.");   /* convert hex to RGB */
   G = inputn(substr(Color, 5, 2), "HEX2.");
   B = inputn(substr(Color, 7, 2), "HEX2.");
end;
if k > 0;
run;

proc sql noprint;
   select Color into :colorlist separated by ' '
   from Colors where Color ne 'cxA23A2E';
quit;

%put &colorlist.;

data A;
do Color = 1 to 20;
   x = Color; y = Color;  output;
end;
run;

proc sgplot data=A;
   *styleattrs Datacolors = (&colorlist.);
   vbar y / group=Color;
run;

Here is the result without the Styleattrs Statement

And here it is without the red color

Re: PROC SGPLOT-removing the red from the default random list of colors

ballardw — Tue, 16 Apr 2019 15:29:45 GMT

@JW_Hyde wrote:

I dont want to use the color red from this random list of colors in the plot. How do I omit the red color from the plot?

Unless you are writing code to explicitly make a random set of colors SAS does not use a "random list of colors". The first color used for the first graph element displayed will be the color defined in the current style for graphcolor1 and/contrast, the second item with graphcolor2 and so on through 12 with typical SAS defined styles. Then an algorithm creates others or reuses depending on options.

Re: PROC SGPLOT-removing the red from the default random list of colors

JW_Hyde — Fri, 19 Apr 2019 13:21:45 GMT

In the end this was the solution I chose. I had to define a color list for 3 dozen colors but I did get something that was more presentable. Just make sure that the color BLUE is not the first color in your list.

Thanks all.