topic Re: BEST WAY TO LEAD A VARIABLE in New SAS User

BEST WAY TO LEAD A VARIABLE

d6k5d3 — Wed, 27 Mar 2019 23:03:02 GMT

For a dataset like the following one:

data example;
input interval zzz;
cards;
99 .345
100 -.398
101 .546
102 .968
103 -.012
104 .489
105 .005;
run;

how can I create 1 lead in variable zzz? I have found people recommending about PROC EXPAND, but I could not work that out. Would you please help?

Thank you.

Regards.

Re: BEST WAY TO LEAD A VARIABLE

Astounding — Wed, 27 Mar 2019 23:47:27 GMT

So what should the results look like? Does the final observation get deleted?

Re: BEST WAY TO LEAD A VARIABLE

Tom — Thu, 28 Mar 2019 01:13:52 GMT

Not sure if there is a BEST way. Here is an easy way. I assume you meant to include that last line of data in your example?

data example;
input interval zzz;
cards;
99 .345
100 -.398
101 .546
102 .968
103 -.012
104 .489
105 .005
;

data want ;
  set example;
  set example(firstobs=2 keep=zzz rename=(zzz=zzz_lead1)) example(obs=1 drop=_all_);
run;

                              zzz_
Obs    interval      zzz      lead1

 1         99       0.345    -0.398
 2        100      -0.398     0.546
 3        101       0.546     0.968
 4        102       0.968    -0.012
 5        103      -0.012     0.489
 6        104       0.489     0.005
 7        105       0.005      .

Re: BEST WAY TO LEAD A VARIABLE

PGStats — Thu, 28 Mar 2019 02:28:30 GMT

People recommending proc expand were right, as long as you have SAS/ETS licenced

proc expand data=example out=want;
id interval;
convert zzz=zzz_lead / transformout=(lead 1);
run;

Re: BEST WAY TO LEAD A VARIABLE

d6k5d3 — Thu, 28 Mar 2019 18:25:47 GMT

Awesome! Worked fine!