topic Re: Proc report - Long instead of wide in New SAS User

Proc report - Long instead of wide

hwangnyc — Mon, 25 Mar 2019 15:07:54 GMT

Hi everyone,

I'm trying to create a report using PROC Report:

Here is the data and code:

data dataexercise;
input Week @@ Status $;
datalines;
1 Accept
2 Accept
3 Accept
4 Accept
1 Reject
2 Reject
3 Accept
4 Accept
1 Accept
2 Accept
3 Accept
4 Accept
;
run;

proc tabulate data=dataexercise;
class week Status ;
table
week*Status;
run;

Instead of the weeks going horizontally. This is what I would like:

Week	Accept	Reject
1	2	1
2	2	1
3	3	0
4	3	0

Any help would be greatly appreciated!

Thank you!

Re: Proc report - Long instead of wide

ballardw — Mon, 25 Mar 2019 15:13:12 GMT

proc tabulate data=dataexercise;
   class week Status ;
   table
       week=' ',
      Status=' '
      /box=week;
run;

The comma is used in tabulate to separate the role from page, row or column. With only two dimensions the first is row, and second is column. The =' ' suppresses the variable label and the /box= option places the label of the variable Week inside the upper left corner of the table.

Re: Proc report - Long instead of wide

hwangnyc — Mon, 25 Mar 2019 15:55:55 GMT

Hi Ballardw,

THANK YOU! This is perfect. Can you tell me how I can sum across the rows?

Re: Proc report - Long instead of wide

ballardw — Mon, 25 Mar 2019 17:18:24 GMT

@hwangnyc wrote:
Hi Ballardw,

THANK YOU! This is perfect. Can you tell me how I can sum across the rows?

proc tabulate data=dataexercise;
   class week Status ;
   table
       week=' ',
      Status=' ' All='Row total'
      /box=week;
run;

will do a row count total for all records in the week

proc tabulate data=dataexercise;
   class week Status ;
   table
       week=' ' all='Column Total',
      Status=' '
      /box=week;
run;

Will do the total across the weeks and;

proc tabulate data=dataexercise;
   class week Status ;
   table
       week=' ' all='Column Total',
      Status=' ' all='Row Total'
      /box=week;
run;

Will provide a total of both row and column.

All can be used in parentheses to work with different groups of values.

Be aware that Proc Tabulate by default will only include records that have values for all of the Class variables by default.