topic Re: PROC REPORT with GROUP in New SAS User

PROC REPORT with GROUP

mariopellegrini — Wed, 27 Feb 2019 17:01:34 GMT

Starting from the following example of PROC REPORT:

data test(keep=state industry income);
set sashelp.prdsale;
State=region;
Industry=prodtype;
Income=actual;
run;
proc report data=TEST;
COLUMN STATE INDUSTRY INCOME ;
DEFINE STATE/display GROUP;
DEFINE industry/display GROUP ;
DEFINE INCOME /ANALYSIS sum;
run;

If I delete the "GROUP" option I get the display of all the rows:

proc report data=TEST;
COLUMN STATE INDUSTRY INCOME ;
DEFINE STATE/display ;
DEFINE industry/display;
DEFINE INCOME /ANALYSIS sum;
run;

I would like to be able to display all the values of "State", without having the multiplication of rows. It's possible?
I would like to get the following report:
State Industry Income
EAST FURNITURE 146471
EAST OFFICE 223790
WEST FURNITURE 144154
WEST OFFICE 215922

Re: PROC REPORT with GROUP

PaigeMiller — Wed, 27 Feb 2019 18:20:27 GMT

If you want all records collapsed into a group, you need to define the variables as GROUP.

proc report data=TEST;
COLUMN STATE INDUSTRY INCOME ;
DEFINE STATE/group ;
DEFINE industry/group;
DEFINE INCOME /ANALYSIS sum;
run;

Re: PROC REPORT with GROUP

mariopellegrini — Thu, 28 Feb 2019 09:29:05 GMT

It does not solve my request. I would like to see the replication of EAST and WEST displayed.
I would like to get the following report:
State Industry Income
EAST FURNITURE 146471
EAST OFFICE 223790
WEST FURNITURE 144154
WEST OFFICE 215922

Re: PROC REPORT with GROUP

PaigeMiller — Thu, 28 Feb 2019 12:56:48 GMT

Then you need to compute the sums using PROC SUMMARY, and then format the table to the way you'd like it using PROC REPORT.

Re: PROC REPORT with GROUP

ssafmed — Mon, 27 May 2019 22:04:21 GMT

Hello Mario,

This procedure solve the problem,

PROC REPORT DATA=TEST;
COLUMN STATE INDUSTRY INCOME;
DEFINE STATE/GROUP;
DEFINE industry/GROUP;
DEFINE INCOME /ANALYSIS sum;
COMPUTE STATE;
IF STATE NE "" THEN DUMMY=STATE;
ELSE STATE=DUMMY;
ENDCOMP;
RUN;

Regards!