topic Re: Proc univariate histogram in New SAS User

Proc univariate histogram

CHELS — Mon, 18 Feb 2019 16:00:44 GMT

Trying to create something similar to the following whereby the legend for the red and green line is within the box.

However, using the code I have, the legend for the line still appears by itself:

proc univariate data=Score noprint plot;
var Predp;
class AAA;
histogram Predp /
kernel (k=normal color=green c = 0.75 l=1);
inset n ='N' (comma6.0) mean ='Mean' (6.2)
median ='Median' (6.2) mode ='Mode'(6.2)/ position=NE;
run;

Re: Proc univariate histogram

Rick_SAS — Mon, 18 Feb 2019 19:15:32 GMT

I see you are using

CLASS AAA;

Is this part of a comparative histogram that appears in a panel?

Re: Proc univariate histogram

CHELS — Mon, 18 Feb 2019 20:59:35 GMT

Yes, so there are two stacked histograms and I want to compare between the two.

Re: Proc univariate histogram

Rick_SAS — Tue, 19 Feb 2019 00:52:24 GMT

But then where do you want the legend?

My advice is to suppress the legend by using the NOCURVELEGEND option and then add the kernel C= value to the inset. Here is an example:

proc univariate data=Sashelp.class noprint plot;
var height;
class sex;
histogram height / NOCURVELEGEND
        kernel (k=normal color=green c = 0.75 l=1);
inset n ='N' (comma6.0) mean ='Mean' (6.2)
        median ='Median' (6.2) mode ='Mode'(6.2) 
        KERNEL(C) / position=NE;
run;

Re: Proc univariate histogram

PGStats — Tue, 19 Feb 2019 04:31:53 GMT

You could go for proc sgplot (more graphing options, fewer estimation options)

proc sgplot data=sashelp.heart;
histogram cholesterol;
density cholesterol / group=sex type=kernel;
keylegend / position=topright location=inside across=1;
run;

Re: Proc univariate histogram

CHELS — Tue, 19 Feb 2019 15:17:08 GMT

I want the legend for the curve to be inside the legend box together with other estimates (N, Mean, Median etc.). Actually, it doesn't make too much of a difference where that curve legend is but I am trying to follow an output template that requires it to be inside the box.