topic Re: automating date variables in entire program in New SAS User

automating date variables in entire program

AdiBoo — Fri, 15 Feb 2019 17:31:20 GMT

Hi,

I am trying to update this program I use, by automating the variables referring to dates.

I have managed to get all the dates in the format I want but now I would like to be able to call them during the program.

ThisDate= Date();  

   FirstDayOfMonth = IntNX("Month", ThisDate, 0);       
   FirstDayOfLastMonth = IntNX("Month", ThisDate, -1);  
   StudyStart = IntNX("Month", ThisDate, -12);            
   StudyEnd = IntNX("Month", ThisDate, 0)-1;
   OneYearAgo = IntNX("Month", ThisDate, -12); 
   date_strt = IntNX("Month", ThisDate, -15);
   date_end = IntNX("Month", ThisDate, -3)-1;
   currentyear = YEAR(FirstDayOfLastMonth);
   curntyear = YEAR(FirstDayOfLastMonth)-2000;
   monthclsng = (MONTH(FirstDayOfLastMonth));
   FirstDayOfYear = IntNX("Year", ThisDate, 0);




 format ThisDate DDMMYY.;
 format FirstDayOfMonth YYMMDDN6.;
 format FirstDayOfLastMonth YYMMDDN6.;
 format OneYearAgo YYMMDDN6.;
 format StudyStart YYMMDDN8.;
 format StudyEnd YYMMDDN8.;
 format date_strt YYMMDDN8.;
 format date_end YYMMDDN8.;
 format monthclsng Z2.;
 format FirstDayOfYear YYMMDDN6.;

I am using SAS 9.3.

Thank you in advance. 🙂

Re: automating date variables in entire program

ballardw — Fri, 15 Feb 2019 17:42:21 GMT

At least give us clue how/ where you want to use these values.

In a single data set then use the data step code you show. Elsewhere we really need to know how you want to use them.

Re: automating date variables in entire program

Astounding — Fri, 15 Feb 2019 17:48:46 GMT

Re: automating date variables in entire program

AdiBoo — Mon, 18 Feb 2019 10:07:40 GMT

Hi,

Thanks for those answers, I indeed could have been a bit more specific.

The finality was to feed the values in that particular format into the following parameters that are use throughout the program.

I've inserted more code below, adding on what I previously sent.

   

data datez ;


   ThisDate= Date();  

   FirstDayOfMonth = IntNX("Month", ThisDate, 0);       
   FirstDayOfLastMonth = IntNX("Month", ThisDate, -1);  
   StudyStart = IntNX("Month", ThisDate, -12);            
   StudyEnd = IntNX("Month", ThisDate, 0)-1;
   OneYearAgo = IntNX("Month", ThisDate, -12); 
   date_strt = IntNX("Month", ThisDate, -15);
   date_end = IntNX("Month", ThisDate, -3)-1;
   currentyear = YEAR(FirstDayOfLastMonth);
   curntyear = YEAR(FirstDayOfLastMonth)-2000;
   monthclsng = (MONTH(FirstDayOfLastMonth));
   FirstDayOfYear = IntNX("Year", ThisDate, 0);




 format ThisDate DDMMYY.;
 format FirstDayOfMonth YYMMDDN6.;
 format FirstDayOfLastMonth YYMMDDN6.;
 format OneYearAgo YYMMDDN6.;
 format StudyStart YYMMDDN8.;
 format StudyEnd YYMMDDN8.;
 format date_strt YYMMDDN8.;
 format date_end YYMMDDN8.;
 format monthclsng Z2.;
 format FirstDayOfYear YYMMDDN6.;

run ;


/* parameters*/

%let base_polvig  = &FirstDayOfMonth    ;      
%let base_polvig_old  = &FirstDayOfLastMonth   ;     
%let base_polvig_old1  = &FirstDayOfYear   ;  
%let base_polvig_old_old  = &OneYearAgo    ; 		
%let annee = &currentyear ; 
%let an   = &curntyear ;
%let mois = &monthclsng ; 
%let deb_etude = &StudyStart ;   
%let fin_etude = &StudyEnd ;  
%let date_deb1 = &date_strt ;   
%let date_fin1 = &date_end;

Thanks 🙂

Re: automating date variables in entire program

Astounding — Mon, 18 Feb 2019 16:44:35 GMT

To accomplish that, replace all the FORMAT statements in the DATA step. Instead of adding a format, transfer the value to a macro variable. For example, you have:

format ThisDate DDMMYY.; format FirstDayOfMonth YYMMDDN6.; format FirstDayOfLastMonth YYMMDDN6.;

Replace that with:

call symputx('ThisDate', put(ThisDate,DDMMYY.));
call symputx('FirstDayOfMonth', put(FirstDayOfMonth, YYMMDDN6.));
call symputx('FirstDayOfLastMonth', put(FirstDayOfLastMonth, YYMMDDN6.));

There's an assumption here that the formatted values will make sense when substituted into your program later.

Re: automating date variables in entire program

AdiBoo — Mon, 15 Apr 2019 09:56:33 GMT

Thanks a lot @Astounding !

I've had time to finish up and the call symputx function works ! 🙂