topic Re: SAS Date Format in New SAS User

SAS Date Format

adityaa9z — Tue, 12 Feb 2019 12:23:02 GMT

Hi Can someone help me with using the informat for this date ?

Feb 5 2019 12:00AM

Also I need the output in mmddyy10. format?

Thanks in advance

Re: SAS Date Format

PeterClemmensen — Tue, 12 Feb 2019 12:49:17 GMT

So you want to read the string "Feb 5 2019 12:00AM" as a date or a datetime value?

Re: SAS Date Format

adityaa9z — Tue, 12 Feb 2019 12:50:44 GMT

Want to read it as DateTime. Want to Write as mmddyy10.

Re: SAS Date Format

Kurt_Bremser — Tue, 12 Feb 2019 12:54:32 GMT

If your datetime comes in this form consistently, the anydtdtm. informat will work:

data want;
indate = 'Feb  5 2019 12:00AM';
outdate = datepart(input(indate,anydtdtm20.));
format outdate mmddyy10.;
run;

proc print data=want noobs;
run;

Result:

      indate              outdate

Feb  5 2019 12:00AM    02/05/2019

Re: SAS Date Format

ballardw — Tue, 12 Feb 2019 15:11:50 GMT

If you want to keep the value as a datetime value you can use a custom format. Example:

Proc format library=work;
picture dtmmddyy    (default=10)
low-high ='%0m/%0d/%Y'   (datatype=datetime)
;
run;

data example;
   x='02FEB2019:10:15:15'dt;
   put x dtmmddyy.;
run;

SAS does supply a number of other formats to display the date portion of datetime values such as DTDATE, DTMONYY and a couple of others. So this is not an off the wall solution.